Тип QML ButtonGroup

Взаимоисключающая группа кнопок с возможностью выбора. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• buttons : список<AbstractButton>
• checkedButton : AbstractButton

Присоединенные свойства

• group : ButtonGroup

Сигналы

• void clicked(AbstractButton button)

Методы

• void addButton(AbstractButton button)
• void removeButton(AbstractButton button)

Подробное описание

ButtonGroup — это невидимая группа взаимоисключающих кнопок. Используется с такими элементами управления, как RadioButton, где можно выбрать только один вариант одновременно.

Наиболее простой способ использования ButtonGroup — назначение списка кнопок. Например, список дочерних элементов позиционера или макета, управляющего группой взаимоисключающих кнопок.

ButtonGroup {
    buttons: column.children
}

Column {
    id: column

    RadioButton {
        checked: true
        text: qsTr("DAB")
    }

    RadioButton {
        text: qsTr("FM")
    }

    RadioButton {
        text: qsTr("AM")
    }
}

Взаимоисключающие кнопки не всегда имеют общий родительский элемент, а родительский макет иногда может содержать элементы, которые не должны включаться в группу кнопок. В таких случаях лучше всего использовать присоединённое свойство group.

ButtonGroup { id: radioGroup }

Column {
    Label {
        text: qsTr("Radio:")
    }

    RadioButton {
        checked: true
        text: qsTr("DAB")
        ButtonGroup.group: radioGroup
    }

    RadioButton {
        text: qsTr("FM")
        ButtonGroup.group: radioGroup
    }

    RadioButton {
        text: qsTr("AM")
        ButtonGroup.group: radioGroup
    }
}

Более сложные случаи использования можно обработать с помощью методов addButton() и removeButton().

См. также RadioButton и Кнопки элементов управления.

Документация по свойствам

[default] buttons : список<AbstractButton>

Это свойство содержит список кнопок.

ButtonGroup {
    buttons: column.children
}

Column {
    id: column

    RadioButton {
        checked: true
        text: qsTr("Option A")
    }

    RadioButton {
        text: qsTr("Option B")
    }
}

См. также group.

checkedButton : AbstractButton

Это свойство содержит текущую выбранную кнопку или null, если таковой нет.

По умолчанию это первая выбранная кнопка, добавленная в группу кнопок.

Документация по присоединённым свойствам

ButtonGroup.group : ButtonGroup

Это свойство присоединяет кнопку к группе кнопок.

ButtonGroup { id: group }

RadioButton {
    checked: true
    text: qsTr("Option A")
    ButtonGroup.group: group
}

RadioButton {
    text: qsTr("Option B")
    ButtonGroup.group: group
}

См. также buttons.

Документация по сигналам

void clicked(AbstractButton button)

Этот сигнал генерируется, когда кнопка button в группе была нажата.

Этот сигнал удобен для реализации обработчика общего сигнала для всех кнопок в одной группе.

ButtonGroup {
    buttons: column.children
    onClicked: console.log("clicked:", button.text)
}

Column {
    id: column
    Button { text: "First" }
    Button { text: "Second" }
    Button { text: "Third" }
}

Этот QML-сигнал был представлен в QtQuick.Controls 2.1 (Qt 5.8).

См. также AbstractButton::clicked().

Документация по методам

void addButton(AbstractButton button)

Добавляет кнопку button в группу кнопок.

Примечание: Вручную добавлять объекты в группу кнопок обычно не нужно. Свойство buttons и присоединённое свойство group предоставляют удобный и декларативный синтаксис.

См. также buttons и group.

void removeButton(AbstractButton button)

Удаляет кнопку button из группы кнопок.

Примечание: Вручную удалять объекты из группы кнопок обычно не нужно. Свойство buttons и присоединённое свойство group предоставляют удобный и декларативный синтаксис.

См. также buttons и group.