Тип QML ToolTip

Предоставляет подсказки для любого элемента управления. Подробнее...

• Список всех членов, включая унаследованные члены

Свойства

• delay : int
• text : строка
• timeout : int

Присоединенные свойства

• delay : int
• text : строка
• timeout : int
• toolTip : ToolTip
• visible : bool

Присоединенные методы

• void hide()
• void show(строка text, int timeout)

Подробное описание

Подсказка — это небольшой фрагмент текста, информирующий пользователя о функции элемента управления. Обычно он размещается над или под родительским элементом управления. Текст подсказки может быть любой форматированной строкой rich text.

Присоединенные подсказки

Самый простой способ настроить подсказки для элементов управления — указать text и видимость с помощью присоединенных свойств. Следующий пример иллюстрирует этот подход:

Button {
    text: qsTr("Save")

    ToolTip.visible: down
    ToolTip.text: qsTr("Save the active project")
}

В обычных условиях одновременно видна только одна подсказка. Для экономии ресурсов все элементы, использующие присоединенное свойство ToolTip, совместно используют один и тот же визуальный ярлык подсказки. Несмотря на то, что визуальные элементы совместно используются, text, timeout и delay хранятся индивидуально для каждого элемента, использующего соответствующее присоединенное свойство. Однако несколько элементов не могут одновременно сделать общую подсказку видимой. Общая подсказка отображается только для последнего элемента, который сделал ее видимой. Положение общей подсказки определяется фреймворком.

Задержка и таймаут

Подсказки обычно являются временными в том смысле, что они отображаются в результате определенного внешнего события или взаимодействия пользователя, и они обычно скрываются после определенного таймаута. Можно контролировать задержку при отображении подсказки и таймаут при ее скрытии. Это позволяет реализовать различные стратегии отображения и скрытия подсказок.

Например, на сенсорных экранах распространенным шаблоном является отображение подсказки в результате удерживания нажатия на кнопку. Следующий пример демонстрирует, как отложить отображение подсказки до момента достижения интервала удерживания нажатия. В этом примере подсказка скрывается сразу после отпускания кнопки.

Button {
    text: qsTr("Button")

    ToolTip.visible: pressed
    ToolTip.delay: Qt.styleHints.mousePressAndHoldInterval
    ToolTip.text: qsTr("This tool tip is shown after pressing and holding the button down.")
}

Однако с устройствами с указательными устройствами может потребоваться отобразить подсказку в результате наведения курсора на кнопку в течение некоторого времени. Следующий пример демонстрирует, как отобразить подсказку после наведения на кнопку в течение секунды и скрыть ее через пять секунд.

Button {
    text: qsTr("Button")
    hoverEnabled: true

    ToolTip.delay: 1000
    ToolTip.timeout: 5000
    ToolTip.visible: hovered
    ToolTip.text: qsTr("This tool tip is shown after hovering the button for a second.")
}

Настраиваемые подсказки

Если требуется более точный контроль над позиционированием подсказки или требуются несколько одновременно отображаемых подсказок, можно также создавать локальные экземпляры подсказок. Таким образом, можно настроить подсказку, и доступен весь API Popup. Следующий пример представляет подсказку, отображающую значение ползунка при перемещении его ручки.

Slider {
    id: slider
    value: 0.5

    ToolTip {
        parent: slider.handle
        visible: slider.pressed
        text: slider.value.toFixed(1)
    }
}

См. также Настройка ToolTip и Элементы управления Popup.

Документация по свойствам

delay : int

Это свойство содержит задержку (в миллисекундах) после которой отображается подсказка. Подсказка с отрицательной задержкой отображается немедленно. Значение по умолчанию — 0.

См. также Задержка и таймаут.

text : строка

Это свойство содержит текст, отображаемый на подсказке.

timeout : int

Это свойство содержит таймаут (в миллисекундах) после которого подсказка скрывается. Подсказка с отрицательным таймаутом автоматически не скрывается. Значение по умолчанию — -1.

См. также Задержка и таймаут.

Документация по присоединенным свойствам

ToolTip.delay : int

Это присоединенное свойство содержит задержку (в миллисекундах) общей подсказки. Свойство можно прикрепить к любому элементу.

См. также Присоединенные подсказки и Задержка и таймаут.

ToolTip.text : строка

Это присоединенное свойство содержит текст общей подсказки. Свойство можно прикрепить к любому элементу.

См. также Присоединенные подсказки.

ToolTip.timeout : int

Это присоединенное свойство содержит таймаут (в миллисекундах) общей подсказки. Свойство можно прикрепить к любому элементу.

См. также Присоединенные подсказки и Задержка и таймаут.

ToolTip.toolTip : ToolTip

Это присоединенное свойство содержит экземпляр общей подсказки. Свойство можно прикрепить к любому элементу.

См. также Присоединенные подсказки.

ToolTip.visible : bool

Это присоединенное свойство указывает, видна ли общая подсказка. Свойство можно прикрепить к любому элементу.

См. также Присоединенные подсказки.

Документация по присоединенным методам

void hide()

Этот присоединенный метод скрывает общую подсказку. Метод можно прикрепить к любому элементу.

См. также Присоединенные подсказки.

void show(строка text, int timeout = -1)

Этот присоединенный метод отображает общую подсказку с text и timeout (в миллисекундах). Метод можно прикрепить к любому элементу.

См. также Присоединенные подсказки.