Тип QML Tumbler

Поворотное колесо элементов, которые можно выбрать. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• count : int
• currentIndex : int
• currentItem : Item
• delegate : Component
• model : variant
• moving : bool
• visibleItemCount : int
• wrap : bool

Присоединённые свойства

• displacement : real
• tumbler : Tumbler

Подробное описание

Tumbler {
    model: 5
    // ...
}

Tumbler позволяет пользователю выбрать вариант из вращающегося "колеса" элементов. Это полезно, когда вариантов слишком много, чтобы использовать, например, RadioButton, и слишком мало, чтобы потребовалось использовать редактируемый SpinBox. Это удобно, так как не требует использования клавиатуры и циклично переходит к началу/концу при большом количестве элементов.

API аналогичен представлению, такому как ListView и PathView; можно задать модель и представление, а свойства count и currentItem предоставляют доступ к информации о представлении.

Однако, в отличие от представлений, таких как PathView и ListView, всегда есть текущий элемент (когда модель не пуста). Это означает, что когда count равно 0, currentIndex будет -1. Во всех остальных случаях он будет больше или равен 0.

По умолчанию, Tumbler циклически переходит к началу и концу, если в модели элементов больше, чем видимых элементов; то есть, когда count больше, чем visibleItemCount:

import QtQuick 2.8
import QtQuick.Window 2.2
import QtQuick.Controls 2.1

Rectangle {
    width: frame.implicitWidth + 10
    height: frame.implicitHeight + 10

    function formatText(count, modelData) {
        var data = count === 12 ? modelData + 1 : modelData;
        return data.toString().length < 2 ? "0" + data : data;
    }

    FontMetrics {
        id: fontMetrics
    }

    Component {
        id: delegateComponent

        Label {
            text: formatText(Tumbler.tumbler.count, modelData)
            opacity: 1.0 - Math.abs(Tumbler.displacement) / (Tumbler.tumbler.visibleItemCount / 2)
            horizontalAlignment: Text.AlignHCenter
            verticalAlignment: Text.AlignVCenter
            font.pixelSize: fontMetrics.font.pixelSize * 1.25
        }
    }

    Frame {
        id: frame
        padding: 0
        anchors.centerIn: parent

        Row {
            id: row

            Tumbler {
                id: hoursTumbler
                model: 12
                delegate: delegateComponent
            }

            Tumbler {
                id: minutesTumbler
                model: 60
                delegate: delegateComponent
            }

            Tumbler {
                id: amPmTumbler
                model: ["AM", "PM"]
                delegate: delegateComponent
            }
        }
    }
}

См. также Настройка Tumbler и Элементы управления вводом.

Документация по свойствам

[только для чтения] count : int

Это свойство содержит количество элементов в модели.

currentIndex : int

Это свойство содержит индекс текущего элемента.

Значение этого свойства равно -1 когда count равно 0. Во всех остальных случаях оно будет больше или равно 0.

[только для чтения] currentItem : Item

Это свойство содержит элемент по текущему индексу.

delegate : Component

Это свойство содержит делегат, используемый для отображения каждого элемента.

model : variant

Это свойство содержит модель, которая предоставляет данные для данного элемента Tumbler.

moving : bool

Это свойство описывает, перемещается ли Tumbler в данный момент, в результате того, что пользователь либо перетаскивает, либо поворачивает его.

Это свойство QML было добавлено в QtQuick.Controls 2.2 (Qt 5.9).

visibleItemCount : int

Это свойство содержит количество видимых элементов в Tumbler. Оно должно быть нечётным числом, так как текущий элемент всегда находится по вертикали посередине.

wrap : bool

Это свойство определяет, переходит ли Tumbler к началу или концу, когда достигает вершины или низа.

Значение по умолчанию равно false когда count меньше visibleItemCount, так как взаимодействовать с нециклическим Tumbler проще, когда есть только несколько элементов. Чтобы переопределить это поведение, явно установите значение этого свойства. Чтобы вернуться к стандартному поведению, установите это свойство в undefined.

Это свойство QML было добавлено в QtQuick.Controls 2.1 (Qt 5.8).

Документация по присоединённому свойству

[только для чтения] Tumbler.displacement : real

Это присоединённое свойство содержит значение от -visibleItemCount / 2 до visibleItemCount / 2, что представляет собой расстояние этого элемента от текущего элемента, при этом 0 означает полное совпадение.

Например, элемент ниже будет на 40% непрозрачным, когда он не текущий элемент, и перейдёт к 100% непрозрачности, когда станет текущим:

delegate: Text {
    text: modelData
    opacity: 0.4 + Math.max(0, 1 - Math.abs(Tumbler.displacement)) * 0.6
}

[только для чтения] Tumbler.tumbler : Tumbler

Это присоединённое свойство содержит Tumbler. Свойство может быть присоединено к делегату tumbler. Значение равно null если элемент не является делегатом tumbler.