Тип QML Repeater

Создаёт несколько компонентов на основе Item, используя предоставленную модель Подробнее...

• Список всех членов, включая унаследованные

Свойства

• count : int
• delegate : Component
• model : any

Сигналы

• itemAdded(int index, Item item)
• itemRemoved(int index, Item item)

Методы

• Item itemAt(index)

Подробное описание

Тип Repeater используется для создания большого количества похожих элементов. Как и другие типы представлений, Repeater имеет свойство model и delegate: для каждой записи в модели компонент delegate создаётся в контексте, заполненном данными из модели. Элемент Repeater обычно заключён в тип позиционера, такой как Row или Column, чтобы визуально расположить несколько элементов delegate, созданных Repeater.

Следующий Repeater создаёт три экземпляра элемента Rectangle внутри Row:

import QtQuick 2.0

Row {
    Repeater {
        model: 3
        Rectangle {
            width: 100; height: 40
            border.width: 1
            color: "yellow"
        }
    }
}

Модель model Repeater может быть любым из поддерживаемых моделей данных. Кроме того, как и делегаты других представлений, делегат Repeater может получить свой индекс в пределах Repeater, а также данные модели, относящиеся к делегату. Подробности см. в документации свойства delegate.

Элементы, созданные Repeater, вставляются по порядку в качестве дочерних элементов родительского элемента Repeater. Вставка начинается сразу после позиции repeater в списке стекирования родительского элемента. Это позволяет использовать Repeater внутри макета. Например, элементы следующего Repeater расположены между красным прямоугольником и синим прямоугольником:

Row {
    Rectangle { width: 10; height: 20; color: "red" }
    Repeater {
        model: 10
        Rectangle { width: 20; height: 20; radius: 10; color: "green" }
    }
    Rectangle { width: 10; height: 20; color: "blue" }
}

Примечание: Элемент Repeater владеет всеми элементами, которые он создаёт. Удаление или динамическое уничтожение элемента, созданного Repeater, приведёт к непредсказуемому поведению.

Рекомендации по использованию Repeater

Тип Repeater создаёт все свои элементы делегата при первом создании repeater. Это может быть неэффективно, если есть большое количество элементов делегата, и не все элементы необходимы для одновременного отображения. В этом случае рассмотрите использование других типов представлений, таких как ListView (который создаёт элементы делегата только при прокрутке в область видимости) или используйте методы динамического создания объектов для создания элементов по мере необходимости.

Также обратите внимание, что Repeater основан на Item и может повторять только объекты, производные от Item. Например, его нельзя использовать для повторения QtObjects:

//bad code
Item {
    Can't repeat QtObject as it doesn't derive from Item.
    Repeater {
        model: 10
        QtObject {}
    }
}

Документация по свойствам

count : int

Это свойство содержит количество элементов в модели.

Примечание: Количество элементов в модели, как сообщается свойством count, может отличаться от количества созданных делегатов, если Repeater в процессе создания делегатов или неправильно настроен.

[default] delegate : Component

Делегат предоставляет шаблон, определяющий каждый элемент, созданный repeater.

Делегаты получают доступ к свойству index для чтения, которое указывает индекс делегата в пределах repeater. Например, следующий делегат Text отображает индекс каждого повторяемого элемента:

Column {
    Repeater {
        model: 10
        Text { text: "I'm item " + index }
    }
}

Если model является списком строк или списком объектов, делегат также получает доступ к свойству modelData для чтения, которое содержит данные строки или объекта. Например:

Column {
    Repeater {
        model: ["apples", "oranges", "pears"]
        Text { text: "Data: " + modelData }
    }
}

Если model является объектом модели (например, ListModel), делегат может получить доступ ко всем ролям модели как к именованным свойствам, аналогично тому, как делегаты делают это для классов представлений, таких как ListView.

См. также QML Модели данных.

model : any

Модель, предоставляющая данные для repeater.

Это свойство может быть установлено в любую из поддерживаемых моделей данных:

• Число, указывающее количество делегатов, которые нужно создать repeater
• Модель (например, элемент ListModel или подкласс QAbstractItemModel)
• Список строк
• Список объектов

Тип модели влияет на свойства, доступные для delegate.

См. также Модели данных.

Документация по сигналам

itemAdded(int index, Item item)

Этот сигнал генерируется при добавлении элемента в repeater. Параметр index содержит индекс, в котором был вставлен элемент внутри repeater, а параметр item содержит добавленный Item.

Соответствующий обработчик — onItemAdded.

itemRemoved(int index, Item item)

Этот сигнал генерируется при удалении элемента из repeater. Параметр index содержит индекс, из которого был удалён элемент из repeater, а параметр item содержит удалённый Item.

Не храните ссылку на item, если он был создан этим repeater, так как в этих случаях он будет удалён вскоре после обработки сигнала.

Соответствующий обработчик — onItemRemoved.

Документация по методам

Item itemAt(index)

Возвращает Item, созданный по заданному индексу, или null если элемент с индексом не существует.