Тип QML RotationAnimation

Анимирует изменения значений поворота Подробнее...

• Список всех членов, включая наследуемые

Свойства

• direction : перечисление
• from : вещественное число
• to : вещественное число

Подробное описание

RotationAnimation — специализированный PropertyAnimation, предоставляющий контроль над направлением вращения во время анимации.

По умолчанию вращение происходит в направлении числового изменения; вращение от 0 до 240 градусов будет осуществляться по часовой стрелке на 240 градусов, а вращение от 240 до 0 — против часовой стрелки на 240 градусов. Свойство direction можно задать для указания направления вращения.

В следующем примере мы используем RotationAnimation для анимации вращения между состояниями по кратчайшему пути:

import QtQuick 2.0

Item {
    width: 300; height: 300

    Rectangle {
        id: rect
        width: 150; height: 100; anchors.centerIn: parent
        color: "red"
        antialiasing: true

        states: State {
            name: "rotated"
            PropertyChanges { target: rect; rotation: 180 }
        }

        transitions: Transition {
            RotationAnimation { duration: 1000; direction: RotationAnimation.Counterclockwise }
        }
    }

    MouseArea { anchors.fill: parent; onClicked: rect.state = "rotated" }
}

Обратите внимание, что RotationAnimation не нужно было устанавливать значение target. Для удобства, при использовании в переходе, RotationAnimation будет вращать все свойства с именами "rotation" или "angle". Это можно переопределить, указав собственные свойства через properties или property.

Также обратите внимание, что Rectangle будет вращаться вокруг своего значения по умолчанию transformOrigin (которое равно Item.Center). Чтобы использовать другое значение transform origin, задайте его в объекте PropertyChanges и примените изменение в начале анимации, используя PropertyAction. Дополнительные сведения см. в документации к PropertyAction.

Как и любой другой тип анимации, RotationAnimation может применяться различными способами, включая переходы, поведения и источники значений свойств. Документация Анимация и переходы в Qt Quick демонстрирует различные методы создания анимаций.

См. также Анимация и переходы в Qt Quick и Примеры Qt Quick — Анимация.

Документация по свойствам

direction : перечисление

Это свойство содержит направление вращения.

Возможные значения:

• RotationAnimation.Numerical (по умолчанию) — Вращение путем линейной интерполяции между двумя числами. Вращение от 10 до 350 градусов будет производиться на 340 градусов по часовой стрелке.
• RotationAnimation.Clockwise — Вращение по часовой стрелке между двумя значениями
• RotationAnimation.Counterclockwise — Вращение против часовой стрелки между двумя значениями
• RotationAnimation.Shortest — Вращение в направлении, которое обеспечивает кратчайший путь анимации. Вращение от 10 до 350 градусов будет производиться на 20 градусов против часовой стрелки.

from : вещественное число

Это свойство содержит начальное значение для анимации.

Например, следующая анимация не применяется, пока значение angle не достигнет 100:

Item {
    states: [
        // ...
    ]

    transition: Transition {
        RotationAnimation { properties: "angle"; from: 100; duration: 2000 }
    }
}

Если RotationAnimation определен в пределах Перехода или Поведения, это значение по умолчанию соответствует значению, определенному в начальном состоянии Перехода, или текущему значению свойства в момент запуска Поведения.

См. также Анимация и переходы в Qt Quick.

to : вещественное число

Это свойство содержит конечное значение для анимации.

Если RotationAnimation определен в пределах Перехода или Поведения, это значение по умолчанию соответствует значению, определенному в конечном состоянии Перехода, или значению изменения свойства, которое вызвало Поведение.

См. также Анимация и переходы в Qt Quick.