Тип QML SmoothedAnimation

Позволяет свойству плавно отслеживать значение Подробнее...

• Список всех членов, включая унаследованные

Свойства

• duration : int
• maximumEasingTime : int
• reversingMode : перечисление
• velocity : вещественное

Подробное описание

SmoothedAnimation анимирует значение свойства до заданного целевого значения с помощью кривой плавного ускорения/замедления (ease in/out quad). При изменении целевого значения кривые плавного ускорения/замедления, используемые для анимации между старым и новым целевыми значениями, плавно соединяются, создавая плавное движение к новому целевому значению, сохраняя текущую скорость.

Следующий пример демонстрирует, как один Rectangle отслеживает положение другого с помощью SmoothedAnimation. Значения x и y зеленого прямоугольника привязаны к значениям красного прямоугольника. Всякий раз, когда эти значения изменяются, зеленый прямоугольник плавно анимируется до нового положения:

import QtQuick 2.0

Rectangle {
    width: 800; height: 600
    color: "blue"

    Rectangle {
        width: 60; height: 60
        x: rect1.x - 5; y: rect1.y - 5
        color: "green"

        Behavior on x { SmoothedAnimation { velocity: 200 } }
        Behavior on y { SmoothedAnimation { velocity: 200 } }
    }

    Rectangle {
        id: rect1
        width: 50; height: 50
        color: "red"
    }

    focus: true
    Keys.onRightPressed: rect1.x = rect1.x + 100
    Keys.onLeftPressed: rect1.x = rect1.x - 100
    Keys.onUpPressed: rect1.y = rect1.y - 100
    Keys.onDownPressed: rect1.y = rect1.y + 100
}

SmoothedAnimation можно настроить, задав скорость анимации velocity или продолжительность анимации duration. Если указаны как скорость, так и продолжительность, для каждого изменения целевого значения используется значение, которое приводит к более быстрой анимации.

Например, анимация от 0 до 800 займет 4 секунды при скорости 200, 8 секунд при продолжительности 8000 и 4 секунды, если заданы как скорость 200, так и продолжительность 8000. Анимация от 0 до 20000 займет 10 секунд при скорости 200, 8 секунд при продолжительности 8000 и 8 секунд, если заданы как скорость 200, так и продолжительность 8000.

По умолчанию скорость SmoothedAnimation составляет 200 единиц/секунду. Обратите внимание, что если диапазон анимируемого значения невелик, скорость необходимо соответствующим образом скорректировать. Например, непрозрачность элемента варьируется от 0 до 1.0. Для плавной анимации в этом диапазоне скорость должна быть установлена в значение, такое как 0.5 единиц/секунду. Анимация от 0 до 1.0 со скоростью 0.5 займет 2000 мс.

Как и любой другой тип анимации, SmoothedAnimation можно применять различными способами, включая переходы, поведения и источники значений свойств. Документация по Анимации и переходам в Qt Quick демонстрирует различные методы создания анимаций.

См. также SpringAnimation, NumberAnimation, Анимации и переходы в Qt Quick и Примеры Qt Quick — Анимации.

Документация по свойствам

duration : int

Это свойство хранит продолжительность анимации в мс, используемой при отслеживании источника.

Установка значения -1 (по умолчанию) отключает значение продолжительности.

Если значения скорости и продолжительности оба включены, анимация будет использовать то, что даёт более короткую продолжительность.

maximumEasingTime : int

Это свойство задает максимальное время в мс, которое могут занимать «плавные» изменения во время отслеживания. Установка этого свойства приводит к «выравниванию» скорости по прошествии определенного времени. Установка отрицательного значения возвращает к обычному режиму плавного изменения на протяжении всей продолжительности анимации.

Значение по умолчанию равно -1.

reversingMode : перечисление

Задает, как SmoothedAnimation ведет себя при изменении направления анимации.

Возможные значения:

• SmoothedAnimation.Eased (по умолчанию) — анимация будет плавно замедлять движение, а затем менять направление
• SmoothedAnimation.Immediate — анимация немедленно начнет ускоряться в обратном направлении, начиная с скорости 0
• SmoothedAnimation.Sync — свойство немедленно устанавливается в целевое значение

velocity : вещественное

Это свойство хранит среднюю скорость, разрешенную при отслеживании целевого значения.

По умолчанию скорость SmoothedAnimation составляет 200 единиц/секунду.

Установка значения -1 отключает значение скорости.

Если значения скорости и продолжительности оба включены, анимация будет использовать то, что даёт более короткую продолжительность.