Тип WorkerScript QML

Позволяет использовать потоки в приложении Qt Quick Подробнее...

• Список всех членов, включая унаследованные

Свойства

• source : url

Сигналы

• message(jsobject msg)

Методы

• sendMessage(jsobject message)

Подробное описание

Используйте WorkerScript для выполнения операций в новом потоке. Это полезно для выполнения операций в фоновом режиме, чтобы основной поток GUI не блокировался.

Сообщения могут передаваться между новым потоком и родительским потоком с помощью sendMessage() и обработчика onMessage().

Пример:

import QtQuick 2.0

Rectangle {
    width: 300; height: 300

    Text {
        id: myText
        text: 'Click anywhere'
    }

    WorkerScript {
        id: myWorker
        source: "script.js"

        onMessage: myText.text = messageObject.reply
    }

    MouseArea {
        anchors.fill: parent
        onClicked: myWorker.sendMessage({ 'x': mouse.x, 'y': mouse.y })
    }
}

Вышеприведенный скрипт рабочего потока определяет файл JavaScript, "script.js", который обрабатывает операции, которые должны выполняться в новом потоке. Вот script.js:

WorkerScript.onMessage = function(message) {
    // ... long-running operations and calculations are done here
    WorkerScript.sendMessage({ 'reply': 'Mouse is at ' + message.x + ',' + message.y })
}

Когда пользователь щелкает в любом месте прямоугольника, sendMessage() вызывается, активируя обработчик WorkerScript.onMessage() в script.js. Это, в свою очередь, отправляет ответное сообщение, которое затем получает обработчик onMessage() myWorker.

Ограничения

Поскольку функция WorkerScript.onMessage() выполняется в отдельном потоке, файл JavaScript оценивается в контексте, отличном от основного движка QML. Это означает, что в отличие от обычного файла JavaScript, импортируемого в QML, script.js в приведенном выше примере не может получить доступ к свойствам, методам или другим атрибутам элемента QML, а также к свойствам контекста, заданным для объекта QML через QQmlContext.

Кроме того, существуют ограничения на типы значений, которые могут передаваться в скрипт рабочего потока и из него. Подробности см. в документации sendMessage().

Скрипт рабочего потока не может использовать синтаксис .import.

См. также Примеры Qt Quick — Потоки и Пример Threaded ListModel.

Документация по свойству

source : url

Здесь хранится URL-адрес файла JavaScript, который реализует обработчик WorkerScript.onMessage() для операций в потоке.

Документация по сигналу

message(jsobject msg)

Этот сигнал излучается при получении сообщения msg от скрипта рабочего потока в другом потоке через вызов sendMessage().

Соответствующий обработчик — onMessage.

Документация по методу

sendMessage(jsobject message)

Отправляет указанное message в обработчик скрипта рабочего потока в другом потоке. Другой обработчик скрипта рабочего потока может получить это сообщение через обработчик onMessage().

Объект message может содержать только значения следующих типов:

• boolean, число, строка
• объекты и массивы JavaScript
• объекты ListModel (любой другой тип QObject* не разрешен)

Все объекты и массивы копируются в message. За исключением объектов ListModel, любые изменения в другом потоке объекта, переданного в message, не будут отражаться в исходном объекте.