Первые шаги с QML

Создание документа QML

Документ QML определяет иерархию объектов с удобочитаемой и структурированной компоновкой. Каждый документ QML состоит из двух частей: секции импорта и секции объявления объекта. Типы и функциональность, наиболее часто используемые в пользовательских интерфейсах, предоставляются в модуле импорта QtQuick.

Импорт и использование модуля Qt Quick

Для использования модуля Qt Quick документ QML должен импортировать его. Синтаксис импорта выглядит следующим образом:

import QtQuick 2.3

Теперь типы и функциональность, предоставляемые Qt Quick, могут быть использованы в документе QML!

Определение иерархии объектов

Объявление объекта в документе QML определяет то, что будет отображено на визуальной сцене. Qt Quick предоставляет основные строительные блоки для всех пользовательских интерфейсов, такие как объекты для отображения изображений и текста, а также для обработки пользовательского ввода.

Простой пример объявления объекта — это цветной прямоугольник с центрированным текстом:

Rectangle {
    width: 200
    height: 100
    color: "red"

    Text {
        anchors.centerIn: parent
        text: "Hello, World!"
    }
}

Это определяет иерархию объектов с корневым объектом Rectangle, который имеет дочерний объект Text. Свойство parent объекта Text автоматически устанавливается в значение Rectangle, и аналогично, объект Text добавляется к свойству children объекта Rectangle в QML.

Объединение всего вместе

Типы Rectangle и Text, используемые в приведенном выше примере, оба предоставляются импортом QtQuick. Объединив импорт и объявление объекта, мы получим полный документ QML:

import QtQuick 2.3

Rectangle {
    width: 200
    height: 100
    color: "red"

    Text {
        anchors.centerIn: parent
        text: "Hello, World!"
    }
}

Если сохранить этот документ как "HelloWorld.qml", его можно загрузить и отобразить.

Создание и запуск проектов QML

Для отображения графической сцены, определенной в документе QML, можно загрузить его с помощью Qt Creator. Для простых файлов пользовательского интерфейса, таких как этот, выберите в Qt Creator Файл > Создать файл или проект > Приложения > Qt Quick UI.

Нажатие на зеленую кнопку Запуск запускает приложение. Вы увидите текст Hello, World! в центре красного прямоугольника.

Дополнительную информацию о создании и запуске проектов в Qt Creator можно найти на следующих страницах:

• Создание проектов Qt Quick
• Сборка и запуск примера

Создание приложений QML с элементами управления

В то время как Qt Quick предоставляет базовые графические элементы, Qt Quick Controls предоставляет готовые типы QML для использования в приложении.

В качестве хорошей отправной точки для создания приложений можно использовать тип ApplicationWindow. Базовая структура пользовательского интерфейса приложения выглядит так:

В каждой области можно добавлять и подключать различные элементы управления для формирования приложения. Например, следующий фрагмент кода представляет собой базовое приложение, использующее предыдущую структуру:

//import related modules
import QtQuick 2.3
import QtQuick.Controls 1.2
import QtQuick.Window 2.2

//window containing the application
ApplicationWindow {

    //title of the application
    title: qsTr("Hello World")
    width: 640
    height: 480

    //menu containing two menu items
    menuBar: MenuBar {
        Menu {
            title: qsTr("File")
            MenuItem {
                text: qsTr("&Open")
                onTriggered: console.log("Open action triggered");
            }
            MenuItem {
                text: qsTr("Exit")
                onTriggered: Qt.quit();
            }
        }
    }

    //Content Area

    //a button in the middle of the content area
    Button {
        text: qsTr("Hello World")
        anchors.horizontalCenter: parent.horizontalCenter
        anchors.verticalCenter: parent.verticalCenter
    }
}

Приложение имеет две пункты меню и кнопку посередине. Нажатие на пункт меню Выход закрывает приложение.

Также доступны различные методы навигации и различные элементы управления, такие как кнопки и ползунки. Следующие примеры доступны в Qt Creator и демонстрируют различные элементы управления и макеты.

• Основные макеты
• Галерея сенсорных устройств

Вы можете скопировать и вставить фрагменты кода в это простое приложение "Hello World", чтобы увидеть, как работает QML.

Обработка пользовательского ввода

Одним из больших преимуществ использования QML для определения пользовательского интерфейса является то, что он позволяет дизайнеру пользовательского интерфейса определять, как приложение должно реагировать на события с помощью простых выражений JavaScript. В QML эти события называются сигналами, и эти сигналы обрабатываются обработчиками сигналов.

Например, рассмотрите следующий пример:

Rectangle {
    width: 200
    height: 100
    color: "red"

    Text {
        anchors.centerIn: parent
        text: "Hello, World!"
    }

    MouseArea {
        anchors.fill: parent
        onClicked: parent.color = "blue"
    }
}

Этот пример можно сохранить как "ClickableHelloWorld.qml" и запустить с помощью qmlscene. Всякий раз, когда пользователь нажимает где-либо в окне, прямоугольник будет меняться с красного на синий. Обратите внимание, что тип MouseArea также испускает сигнал clicked для событий касания, поэтому этот код также будет работать на мобильном устройстве.

Ввод с клавиатуры можно аналогично обрабатывать с помощью простого выражения:

Rectangle {
    width: 200
    height: 100
    color: "red"

    Text {
        anchors.centerIn: parent
        text: "Hello, World!"
    }

    focus: true
    Keys.onPressed: {
        if (event.key == Qt.Key_Return) {
            color = "blue";
            event.accepted = true;
        }
    }
}

При получении фокуса цвет может изменяться на синий при нажатии клавиши ввода.

Связывание свойств

Объекты и их свойства являются основой графического интерфейса, определенного в документе QML. Язык QML позволяет связывать свойства друг с другом различными способами, обеспечивая высокую динамичность пользовательских интерфейсов.

В приведенном ниже примере геометрия каждого дочернего Rectangle связана с геометрией родительского Rectangle. Если геометрия родительского Rectangle изменится, геометрия каждого дочернего Rectangle автоматически обновится благодаря связыванию свойств.

Rectangle {
    width: 400
    height: 200

    Rectangle {
        width: parent.width / 2
        height: parent.height
    }

    Rectangle {
        width: parent.width / 2
        height: parent.height
        x: parent.width / 2
    }
}

Анимации

Свойства также могут быть динамически обновлены с помощью анимаций. Импорт QtQuick предоставляет различные типы анимаций, которые могут быть использованы для анимации изменения значения свойства. В следующем примере свойство анимируется, а затем отображается в области Text:

Rectangle {
    color: "lightgray"
    width: 200
    height: 200

    property int animatedValue: 0
    SequentialAnimation on animatedValue {
        loops: Animation.Infinite
        PropertyAnimation { to: 150; duration: 1000 }
        PropertyAnimation { to: 0; duration: 1000 }
    }

    Text {
        anchors.centerIn: parent
        text: parent.animatedValue
    }
}

Отображаемое значение будет периодически изменяться от 0 до 150.

Определение пользовательских типов QML для повторного использования

Одним из самых важных концепций в QML является повторное использование типов. Приложение, вероятно, будет иметь несколько визуальных типов, которые все похожи (например, несколько кнопок), и QML позволяет определять такие вещи как многократно используемые, пользовательские типы, чтобы минимизировать дублирование кода и максимизировать удобочитаемость.

Например, предположим, что разработчик определил новый тип Button в файле Button.qml.

// Button.qml
import QtQuick 2.3

Rectangle {
    width: 100; height: 100
    color: "red"

    MouseArea {
        anchors.fill: parent
        onClicked: console.log("Button clicked!")
    }
}

Теперь этот тип можно использовать несколько раз в приложении, как показано ниже:

// application.qml
import QtQuick 2.3

Column {
    Button { width: 50; height: 50 }
    Button { x: 50; width: 100; height: 50; color: "blue" }
    Button { width: 50; height: 50; radius: 8 }
}

Таким образом, собираются и повторно используются модульные типы пользовательского интерфейса в приложении.

См. Атрибуты объекта QML для получения дополнительной информации о разработке собственных многократно используемых компонентов.

Что делать дальше

Теперь, когда вы увидели QML в действии, вы готовы сделать следующий шаг. Следующая страница проведет вас в вашем путешествии с QML.

• Приложения QML
• Примеры и учебные пособия Qt