Тип QML MenuItemGroup

Группа для управления элементами нативного меню. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• checkedItem : MenuItem
• enabled : bool
• exclusive : bool
• items : список<MenuItem>
• visible : bool

Сигналы

• hovered(MenuItem item)
• triggered(MenuItem item)

Методы

• void addItem(MenuItem item)
• void clear()
• void removeItem(MenuItem item)

Подробное описание

Группа MenuItemGroup объединяет элементы нативного меню.

MenuItemGroup по умолчанию является эксклюзивной. В группе эксклюзивных элементов меню только один элемент может быть выбран в любой момент времени; выбор другого элемента автоматически сбрасывает предыдущий выбор. MenuItemGroup можно настроить как неэксклюзивный, что особенно полезно для совместного отображения, скрытия, включения и выключения элементов в группе.

Наиболее простой способ использования MenuItemGroup — назначить список элементов.

Menu {
    id: verticalMenu
    title: qsTr("Vertical")

    MenuItemGroup {
        id: verticalGroup
        items: verticalMenu.items
    }

    MenuItem { text: qsTr("Top"); checkable: true }
    MenuItem { text: qsTr("Center"); checked: true }
    MenuItem { text: qsTr("Bottom"); checkable: true }
}

Иногда в одном меню могут содержаться элементы, которые не должны включаться в одну и ту же эксклюзивную группу. Такие случаи лучше всего обрабатывать с помощью свойства group.

Menu {
    id: horizontalMenu
    title: qsTr("Horizontal")

    MenuItemGroup {
        id: horizontalGroup
    }

    MenuItem {
        checked: true
        text: qsTr("Left")
        group: horizontalGroup
    }
    MenuItem {
        checkable: true
        text: qsTr("Center")
        group: horizontalGroup
    }
    MenuItem {
        text: qsTr("Right")
        checkable: true
        group: horizontalGroup
    }

    MenuItem { separator: true }
    MenuItem { text: qsTr("Justify"); checkable: true }
    MenuItem { text: qsTr("Absolute"); checkable: true }
}

Более сложные случаи можно обработать с помощью методов addItem() и removeItem().

Примечание: Типы в модулях Qt.labs не гарантируют совместимость в будущих версиях.

См. также MenuItem.

Документация по свойствам

checkedItem : MenuItem

Это свойство содержит текущий выбранный элемент в группе или null , если ни один элемент не выбран.

enabled : bool

Это свойство указывает, включена ли группа. Значение по умолчанию — true.

Состояние включения группы влияет на состояние включения каждого элемента в группе, за исключением явно отключенных элементов, которые не включаются, даже если группа включена.

exclusive : bool

Это свойство указывает, является ли группа эксклюзивной. Значение по умолчанию — true.

В группе эксклюзивных элементов меню только один элемент может быть выбран в любой момент времени; выбор другого элемента автоматически сбрасывает предыдущий выбор.

items : список<MenuItem>

Это свойство содержит список элементов в группе.

visible : bool

Это свойство указывает, отображается ли группа. Значение по умолчанию — true.

Видимость группы влияет на видимость каждого элемента в группе, за исключением явно скрытых элементов, которые не видны, даже если группа видима.

Документация по сигналам

hovered(MenuItem item)

Этот сигнал генерируется, когда пользователь наводит указатель мыши на item в группе.

Примечание: Соответствующий обработчик — onHovered.

См. также MenuItem::hovered().

triggered(MenuItem item)

Этот сигнал генерируется, когда пользователь запускает item в группе.

Примечание: Соответствующий обработчик — onTriggered.

См. также MenuItem::triggered().

Документация по методам

void addItem(MenuItem item)

Добавляет item в группу.

void clear()

Удаляет все элементы из группы.

void removeItem(MenuItem item)

Удаляет item из группы.