Тип компонента QML

Инкапсулирует определение компонента QML. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• progress : вещественное
• status : перечисление
• url : url

Присоединенные сигналы

• completed()
• destruction()

Методы

• объект createObject(QtObject parent, объект properties)
• строка errorString()
• объект incubateObject(Элемент parent, объект properties, перечисление mode)

Подробное описание

Компоненты — это повторно используемые, инкапсулированные типы QML с хорошо определенными интерфейсами.

Компоненты часто определяются файлами компонентов — то есть .qml файлами. Тип Component по сути позволяет определять QML-компоненты непосредственно в документе QML, а не в отдельном файле QML. Это может быть полезно для повторного использования небольшого компонента внутри файла QML или для определения компонента, который логически принадлежит другим QML-компонентам в файле.

Например, вот компонент, который используется несколькими объектами Loader. Он содержит один элемент — прямоугольник Rectangle:

import QtQuick 2.0

Item {
    width: 100; height: 100

    Component {
        id: redSquare

        Rectangle {
            color: "red"
            width: 10
            height: 10
        }
    }

    Loader { sourceComponent: redSquare }
    Loader { sourceComponent: redSquare; x: 20 }
}

Обратите внимание, что, хотя сам Rectangle автоматически отображается и выводится на экран, это не относится к прямоугольнику выше, так как он определен внутри Component. Компонент инкапсулирует типы QML внутри, как если бы они были определены в отдельном QML-файле, и загружается только по запросу (в данном случае двумя объектами Loader). Так как Component не наследуется от Item, вы не можете привязать ничего к нему.

Определение Component аналогично определению документа QML. QML-документ имеет один главный элемент верхнего уровня, который определяет поведение и свойства этого компонента, и не может определять свойства или поведение вне этого элемента верхнего уровня. Точно так же определение Component содержит один элемент верхнего уровня (который в приведенном выше примере представляет собой Rectangle) и не может определять какие-либо данные вне этого элемента, за исключением id (который в приведенном выше примере — redSquare).

Тип Component обычно используется для предоставления графических компонентов для представлений. Например, свойство ListView::delegate требует Component для указания того, как должен отображаться каждый элемент списка.

Component объекты также можно создавать динамически с помощью Qt.createComponent().

Контекст создания

Контекст создания компонента соответствует контексту, в котором компонент был объявлен. Этот контекст используется в качестве родительского контекста (создание иерархии контекстов) при создании экземпляра компонента объектом, таким как ListView или Loader.

В следующем примере comp1 создается в корневом контексте MyItem.qml, и любые объекты, созданные из этого компонента, будут иметь доступ к идентификаторам и свойствам в этом контексте, таким как internalSettings.color. Когда comp1 используется в качестве делегата ListView в другом контексте (как в main.qml ниже), он по-прежнему будет иметь доступ к свойствам своего контекста создания (которые в противном случае были бы скрыты от внешних пользователей).

Item {
    property Component mycomponent: comp1

    QtObject {
        id: internalSettings
        property color color: "green"
    }

    Component {
        id: comp1
        Rectangle { color: internalSettings.color; width: 400; height: 50 }
    }
}

ListView {
    width: 400; height: 400
    model: 5
    delegate: myItem.mycomponent    //will create green Rectangles

    MyItem { id: myItem }
}

Важно, чтобы срок службы контекста создания превышал срок службы любых созданных объектов. Более подробную информацию см. в разделе Поддержание динамически созданных объектов.

Документация по свойствам

progress : вещественное

Прогресс загрузки компонента от 0,0 (ничего не загружено) до 1,0 (загрузка завершена).

status : перечисление

Это свойство содержит статус загрузки компонента. Статус может быть одним из следующих:

• Component.Null — данные для компонента недоступны
• Component.Ready — компонент загружен и может использоваться для создания экземпляров.
• Component.Loading — компонент в процессе загрузки
• Component.Error — при загрузке компонента произошла ошибка. Вызов errorString() предоставит удобочитаемое описание любых ошибок.

url : url

URL компонента. Это URL, который использовался для построения компонента.

Документация по присоединенным сигналам

completed()

Выполняется после того, как объект был создан. Это можно использовать для выполнения кода сценария при запуске, как только будет создана полная QML-среда.

Обработчик сигнала onCompleted может быть объявлен в любом объекте. Порядок выполнения обработчиков не определен.

Rectangle {
    Component.onCompleted: console.log("Completed Running!")
    Rectangle {
        Component.onCompleted: console.log("Nested Completed Running!")
    }
}

Примечание: Соответствующий обработчик — onCompleted.

destruction()

Выполняется при начале уничтожения объекта. Это можно использовать для отмены работ, выполненных в ответ на сигнал completed() или других императивных кодов в вашем приложении.

Обработчик сигнала onDestruction может быть объявлен в любом объекте. Порядок выполнения обработчиков не определен.

Rectangle {
    Component.onDestruction: console.log("Destruction Beginning!")
    Rectangle {
        Component.onDestruction: console.log("Nested Destruction Beginning!")
    }
}

Примечание: Соответствующий обработчик — onDestruction.

См. также Qt QML.

Документация по методам

объект createObject(QtObject parent, объект properties)

Создает и возвращает экземпляр объекта этого компонента, который будет иметь указанный parent и properties. Аргумент properties является необязательным. Возвращает null, если создание объекта завершилось неудачей.

Объект будет создан в том же контексте, в котором был создан компонент. Эта функция всегда возвращает null при вызове на компонентах, которые не были созданы в QML.

Если вы хотите создать объект без задания родителя, укажите null для значения parent. Обратите внимание, что если возвращаемый объект должен быть отображен, вы должны предоставить действительное значение parent или установить свойство parent возвращаемого объекта, в противном случае объект не будет виден.

Если parent не задан для createObject(), ссылка на возвращаемый объект должна храниться, чтобы объект не был уничтожен сборщиком мусора. Это справедливо независимо от того, установлено ли Item::parent впоследствии, так как установка родителя Item не изменяет владение объектом. Меняется только графический родитель.

Начиная с QtQuick 1.1, этот метод принимает необязательный аргумент properties, который определяет карту начальных значений свойств для созданного объекта. Эти значения применяются до окончательного завершения создания объекта. Это более эффективно, чем установка значений свойств после создания объекта, особенно в тех случаях, когда определены большие наборы значений свойств, а также позволяет настроить привязки свойств (с помощью Qt.binding) до создания объекта.

Аргумент properties задается как карта элементов свойство-значение. Например, код ниже создает объект с начальными x и y значениями 100 и 100 соответственно:

var component = Qt.createComponent("Button.qml");
if (component.status == Component.Ready)
    component.createObject(parent, {x: 100, y: 100});

Динамически созданные экземпляры можно удалить с помощью метода destroy(). Дополнительную информацию см. в разделе Динамическое создание QML-объектов из JavaScript.

См. также incubateObject().

строка errorString()

Возвращает удобочитаемое описание любой ошибки.

Строка включает файл, расположение и описание каждой ошибки. Если присутствует несколько ошибок, они разделяются символом новой строки.

Если ошибок нет, возвращается пустая строка.

объект incubateObject(Элемент parent, объект properties, перечисление mode)

Создает инкубатор для экземпляра этого компонента. Инкубаторы позволяют асинхронно создавать новые экземпляры компонентов и не вызывают зависаний в пользовательском интерфейсе.

Аргумент parent указывает родителя, который будет у созданного экземпляра. Пропуск параметра или передача null приведет к созданию объекта без родителя. В этом случае ссылка на созданный объект должна храниться, чтобы он не был уничтожен сборщиком мусора.

Аргумент properties задаётся как карта элементов свойство-значение, которые будут установлены на созданный объект во время его построения. mode может быть Qt.Synchronous или Qt.Asynchronous и управляет тем, создаётся ли экземпляр синхронно или асинхронно. По умолчанию используется асинхронный режим. В некоторых случаях, даже если указано Qt.Synchronous, инкубатор может создать объект асинхронно. Это происходит, если компонент, вызывающий incubateObject(), сам создаётся асинхронно.

Все три аргумента являются необязательными.

При успешном выполнении метод возвращает инкубатор, в противном случае null. У инкубатора есть следующие свойства:

• status Статус инкубатора. Допустимые значения: Component.Ready, Component.Loading и Component.Error.
• object Созданный экземпляр объекта. Будет доступен только после того, как инкубатор перейдёт в состояние Ready.
• onStatusChanged Указывает функцию обратного вызова, которая должна вызываться при изменении статуса. Статус передаётся в качестве параметра обратному вызову.
• forceCompletion() Вызов для завершения инкубации синхронно.

Следующий пример демонстрирует, как использовать инкубатор:

var component = Qt.createComponent("Button.qml");

var incubator = component.incubateObject(parent, { x: 10, y: 10 });
if (incubator.status != Component.Ready) {
    incubator.onStatusChanged = function(status) {
        if (status == Component.Ready) {
            print ("Object", incubator.object, "is now ready!");
        }
    }
} else {
    print ("Object", incubator.object, "is ready immediately!");
}

Динамически созданные экземпляры можно удалить с помощью метода destroy(). Дополнительную информацию см. в статье Динамическое создание QML объектов из JavaScript.

См. такжеcreateObject().