Тип WorkerScript QML

Позволяет использовать потоки в приложении Qt Quick. Подробнее...

• Список всех членов, включая наследуемые члены

Свойства

• ready : bool
• source : url

Сигналы

• message(jsobject msg)

Методы

• sendMessage(jsobject message)

Подробное описание

Используйте WorkerScript для выполнения операций в новом потоке. Это полезно для выполнения операций в фоновом режиме, чтобы основной поток графического интерфейса не блокировался.

Сообщения могут передаваться между новым потоком и родительским потоком с помощью sendMessage() и обработчика onMessage().

Пример:

import QtQuick 2.0

Rectangle {
    width: 300; height: 300

    Text {
        id: myText
        text: 'Click anywhere'
    }

    WorkerScript {
        id: myWorker
        source: "script.mjs"

        onMessage: myText.text = messageObject.reply
    }

    MouseArea {
        anchors.fill: parent
        onClicked: myWorker.sendMessage({ 'x': mouse.x, 'y': mouse.y })
    }
}

Вышеупомянутый скрипт рабочего потока указывает на файл JavaScript «script.mjs», который обрабатывает операции, которые должны выполняться в новом потоке. Вот script.mjs:

WorkerScript.onMessage = function(message) {
    // ... long-running operations and calculations are done here
    WorkerScript.sendMessage({ 'reply': 'Mouse is at ' + message.x + ',' + message.y })
}

Когда пользователь нажимает в любом месте прямоугольника, sendMessage() вызывается, вызывая обработчик WorkerScript.onMessage() в script.mjs. Это, в свою очередь, отправляет сообщение с ответом, которое затем получает обработчик onMessage() myWorker.

В примере используется скрипт, который является модулем ECMAScript, поскольку он имеет расширение «.mjs». Он может использовать инструкции импорта для доступа к функциональности из других модулей и выполняется в строгом режиме JavaScript.

Если скрипт рабочего потока имеет расширение «.js», то он считается содержащим обычные инструкции JavaScript и выполняется в нестрогом режиме.

Примечание: Каждый элемент WorkerScript создаст отдельный движок JavaScript для обеспечения полной изоляции и безопасности потоков. Если это оказывает слишком сильное влияние на потребление памяти вашей среды, рассмотрите возможность совместного использования элемента WorkerScript.

Ограничения

Поскольку функция WorkerScript.onMessage() выполняется в отдельном потоке, файл JavaScript оценивается в контексте, отличном от основного движка QML. Это означает, что, в отличие от обычного файла JavaScript, который импортируется в QML, script.mjs в приведенном выше примере не может получить доступ к свойствам, методам или другим атрибутам элемента QML, а также к любым свойствам контекста, заданным для объекта QML через QQmlContext.

Кроме того, существуют ограничения на типы значений, которые могут передаваться в скрипт рабочего потока и из него. Подробности см. в документации к sendMessage().

Скрипты рабочих потоков, которые представляют собой обычные исходные коды JavaScript, не могут использовать синтаксис .import. Скрипты, являющиеся модулями ECMAScript, могут свободно использовать инструкции импорта и экспорта.

См. также Примеры Qt Quick - Потоки и Пример Threaded ListModel.

Документация по свойствам

ready : bool

Здесь указано, был ли инициализирован WorkerScript и готов ли он к приёму сообщений через WorkerScript.sendMessage().

source : url

Здесь указан URL-адрес файла JavaScript, который реализует обработчик WorkerScript.onMessage() для операций в потоке.

Если компонент имени файла в URL-адресе заканчивается на «.mjs», то скрипт интерпретируется как модуль ECMAScript и выполняется в строгом режиме. В противном случае он рассматривается как обычный скрипт.

Документация по сигналам

message(jsobject msg)

Этот сигнал испускается, когда сообщение msg получено из скрипта рабочего потока в другом потоке через вызов sendMessage().

Примечание: Соответствующий обработчик — onMessage.

Документация по методам

sendMessage(jsobject message)

Отправляет заданное message обработчику скрипта рабочего потока в другом потоке. Другой обработчик скрипта рабочего потока может получить это сообщение через обработчик onMessage().

Объект message может содержать только значения следующих типов:

• boolean, number, string
• объекты и массивы JavaScript
• объекты ListModel (любой другой тип QObject* недопустим)

Все объекты и массивы копируются в message. За исключением объектов ListModel, любые изменения в объекте, переданном в message другим потоком, не будут отражены в исходном объекте.