Тип QML PropertyAnimation

Анимирует изменения значений свойств. Подробнее...

• Список всех членов, включая наследуемые

Свойства

• duration : int
• easing
  • easing.amplitude : real
  • easing.bezierCurve : список<real>
  • easing.overshoot : real
  • easing.period : real
  • easing.type : перечисление
• exclude : список<Объект>
• from : вариант
• properties : строка
• property : строка
• target : Объект
• targets : список<Объект>
• to : вариант

Подробное описание

PropertyAnimation предоставляет способ анимировать изменения значения свойства.

Его можно использовать для определения анимаций различными способами:

• В Переходе

  Например, чтобы анимировать любые объекты, которые изменили свои x или y свойства в результате изменения состояния, используя кривую InOutQuad:

  Rectangle {
      id: rect
      width: 100; height: 100
      color: "red"
  
      states: State {
          name: "moved"
          PropertyChanges { target: rect; x: 50 }
      }
  
      transitions: Transition {
          PropertyAnimation { properties: "x,y"; easing.type: Easing.InOutQuad }
      }
  }

• В Поведении

  Например, чтобы анимировать все изменения свойства x прямоугольника:

  Rectangle {
      width: 100; height: 100
      color: "red"
  
      Behavior on x { PropertyAnimation {} }
  
      MouseArea { anchors.fill: parent; onClicked: parent.x = 50 }
  }

• В качестве источника значения свойства

  Например, для многократной анимации свойства x прямоугольника:

  Rectangle {
      width: 100; height: 100
      color: "red"
  
      SequentialAnimation on x {
          loops: Animation.Infinite
          PropertyAnimation { to: 50 }
          PropertyAnimation { to: 0 }
      }
  }

• В обработчике сигнала

  Например, для плавного исчезновения theObject при нажатии:

  MouseArea {
      anchors.fill: theObject
      onClicked: PropertyAnimation { target: theObject; property: "opacity"; to: 0 }
  }

• Самостоятельно

  Например, для анимации свойства rect width в течение 500 мс, от текущей ширины до 30:

  Rectangle {
      id: theRect
      width: 100; height: 100
      color: "red"
  
      // this is a standalone animation, it's not running by default
      PropertyAnimation { id: animation;
                          target: theRect;
                          property: "width";
                          to: 30;
                          duration: 500 }
  
      MouseArea { anchors.fill: parent; onClicked: animation.running = true }
  }

В зависимости от того, как используется анимация, набор обычно используемых свойств будет отличаться. Дополнительную информацию см. в документации по отдельным свойствам, а также в руководстве Анимация и переходы в Qt Quick.

Обратите внимание, что PropertyAnimation наследует абстрактный тип Animation. Это включает дополнительные свойства и методы для управления анимацией.

См. также Анимация и переходы в Qt Quick и Примеры Qt Quick — Анимация.

Документация по свойствам

Эти свойства используются как набор, чтобы определить, какие свойства должны быть анимированы. Единственное и множественное число функционально идентичны, например:

NumberAnimation { target: theItem; property: "x"; to: 500 }

имеет то же значение, что и

NumberAnimation { targets: theItem; properties: "x"; to: 500 }

Единственное число немного оптимизировано, поэтому, если вы хотите анимировать только один целевой объект/свойство, вы должны попробовать использовать их.

Свойство targets позволяет задать несколько целевых объектов. Например, это анимирует свойство x как для itemA, так и для itemB.

NumberAnimation { targets: [itemA, itemB]; properties: "x"; to: 500 }

Во многих случаях эти свойства не нужно явно указывать, так как их можно вывести из фреймворка анимации:

Rectangle {
    id: theRect
    width: 100; height: 100
    color: Qt.rgba(0,0,1)
    NumberAnimation on x { to: 500; loops: Animation.Infinite } //animate theRect's x property
    Behavior on y { NumberAnimation {} } //animate theRect's y property
}

Rectangle {
    id: theRect
    width: 100; height: 100
    color: Qt.rgba(0,0,1)
    Item { id: uselessItem }
    states: State {
        name: "state1"
        PropertyChanges { target: theRect; x: 200; y: 200; z: 4 }
        PropertyChanges { target: uselessItem; x: 10; y: 10; z: 2 }
    }
    transitions: Transition {
        //animate both theRect's and uselessItem's x and y to their final values
        NumberAnimation { properties: "x,y" }

        //animate theRect's z to its final value
        NumberAnimation { target: theRect; property: "z" }
    }
}

Rectangle {
    id: theRect
    width: 100; height: 100
    color: Qt.rgba(0,0,1)
    //need to explicitly specify target and property
    NumberAnimation { id: theAnim; target: theRect; property: "x"; to: 500 }
    MouseArea {
        anchors.fill: parent
        onClicked: theAnim.start()
    }
}

Как видно из приведенного выше примера, свойства указываются как разделяемая запятыми строка имен свойств для анимации.

См. также exclude и Анимация и переходы в Qt Quick.

duration : int

Это свойство содержит продолжительность анимации в миллисекундах.

Значение по умолчанию — 250.

easing.amplitude : real

Указывает кривую плавного изменения, используемую для анимации

Для указания кривой плавного изменения вам необходимо указать как минимум тип. Для некоторых кривых вы также можете указать амплитуду, период и/или перескок (подробнее после таблицы). Кривая плавного изменения по умолчанию — Easing.Linear.

PropertyAnimation { properties: "y";
                    easing.type: Easing.InOutElastic;
                    easing.amplitude: 2.0;
                    easing.period: 1.5 }

Доступные типы:

Easing.Linear	Кривая смягчения для линейной (t) функции: скорость постоянна.
Easing.InQuad	Кривая смягчения для квадратичной (t^2) функции: ускорение от нулевой скорости.
Easing.OutQuad	Кривая смягчения для квадратичной (t^2) функции: замедление до нулевой скорости.
Easing.InOutQuad	Кривая смягчения для квадратичной (t^2) функции: ускорение до середины, затем замедление.
Easing.OutInQuad	Кривая смягчения для квадратичной (t^2) функции: замедление до середины, затем ускорение.
Easing.InCubic	Кривая смягчения для кубической (t^3) функции: ускорение от нулевой скорости.
Easing.OutCubic	Кривая смягчения для кубической (t^3) функции: замедление до нулевой скорости.
Easing.InOutCubic	Кривая смягчения для кубической (t^3) функции: ускорение до середины, затем замедление.
Easing.OutInCubic	Кривая смягчения для кубической (t^3) функции: замедление до середины, затем ускорение.
Easing.InQuart	Кривая смягчения для четвёртой степени (t^4) функции: ускорение от нулевой скорости.
Easing.OutQuart	Кривая смягчения для четвёртой степени (t^4) функции: замедление до нулевой скорости.
Easing.InOutQuart	Кривая смягчения для четвёртой степени (t^4) функции: ускорение до середины, затем замедление.
Easing.OutInQuart	Кривая смягчения для четвёртой степени (t^4) функции: замедление до середины, затем ускорение.
Easing.InQuint	Кривая смягчения для пятой степени (t^5) функции: ускорение от нулевой скорости.
Easing.OutQuint	Кривая смягчения для пятой степени (t^5) функции: замедление до нулевой скорости.
Easing.InOutQuint	Кривая смягчения для пятой степени (t^5) функции: ускорение до середины, затем замедление.
Easing.OutInQuint	Кривая смягчения для синусоидальной (sin(t)) функции: ускорение от нулевой скорости.
Easing.InSine	Кривая смягчения для синусоидальной (sin(t)) функции: замедление до нулевой скорости.
Easing.OutSine	Кривая смягчения для синусоидальной (sin(t)) функции: ускорение до середины, затем замедление.
Easing.InOutSine	Кривая смягчения для синусоидальной (sin(t)) функции: замедление до середины, затем ускорение.
Easing.OutInSine	Кривая смягчения для экспоненциальной (2^t) функции: ускорение от нулевой скорости.
Easing.InExpo	Кривая смягчения для экспоненциальной (2^t) функции: замедление до нулевой скорости.
Easing.OutExpo	Кривая смягчения для экспоненциальной (2^t) функции: ускорение до середины, затем замедление.
Easing.InOutExpo	Кривая смягчения для экспоненциальной (2^t) функции: замедление до середины, затем ускорение.
Easing.OutInExpo	Кривая смягчения для круговой (sqrt(1-t^2)) функции: ускорение от нулевой скорости.
Easing.InCirc	Кривая смягчения для круговой (sqrt(1-t^2)) функции: замедление до нулевой скорости.
Easing.OutCirc	Кривая смягчения для круговой (sqrt(1-t^2)) функции: ускорение до середины, затем замедление.
Easing.InOutCirc	Кривая смягчения для круговой (sqrt(1-t^2)) функции: замедление до середины, затем ускорение.
Easing.OutInCirc	Кривая смягчения для упругой (экспоненциально затухающая синусоидальная) функции: ускорение от нулевой скорости. Пиковая амплитуда может быть установлена с помощью параметра amplitude, а период затухания — параметром period.
Easing.InElastic	Кривая смягчения для упругой (экспоненциально затухающая синусоидальная) функции: замедление до нулевой скорости. Пиковая амплитуда может быть установлена с помощью параметра amplitude, а период затухания — параметром period.
Easing.OutElastic	Кривая смягчения для упругой (экспоненциально затухающая синусоидальная) функции: ускорение до середины, затем замедление.
Easing.InOutElastic	Кривая смягчения для упругой (экспоненциально затухающая синусоидальная) функции: замедление до середины, затем ускорение.
Easing.OutInElastic	Кривая смягчения для обратной (перескок кубической функции: (s+1)*t^3 - s*t^2) easing in: ускорение от нулевой скорости.
Easing.InBack	Кривая смягчения для обратной (перескок кубической функции: (s+1)*t^3 - s*t^2) easing out: замедление до нулевой скорости.
Easing.OutBack	Кривая смягчения для обратной (перескок кубической функции: (s+1)*t^3 - s*t^2) easing in/out: ускорение до середины, затем замедление.
Easing.InOutBack	Кривая смягчения для обратной (перескок кубической функции: (s+1)*t^3 - s*t^2) easing out/in: замедление до середины, затем ускорение.
Easing.OutInBack	Кривая смягчения для отскока (экспоненциально затухающий параболический отскок) функции: ускорение от нулевой скорости.
Easing.InBounce	Кривая смягчения для отскока (экспоненциально затухающий параболический отскок) функции: замедление до нулевой скорости.
Easing.OutBounce	Кривая смягчения для отскока (экспоненциально затухающий параболический отскок) функции easing in/out: ускорение до середины, затем замедление.
Easing.InOutBounce	Кривая смягчения для отскока (экспоненциально затухающий параболический отскок) функции easing out/in: замедление до середины, затем ускорение.
Easing.OutInBounce	Пользовательская кривая смягчения, определенная свойством easing.bezierCurve.

easing.amplitude применима только для кривых отскока и упругих кривых (кривые типа Easing.InBounce, Easing.OutBounce, Easing.InOutBounce, Easing.OutInBounce, Easing.InElastic, Easing.OutElastic, Easing.InOutElastic или Easing.OutInElastic).

easing.overshoot применима только если easing.type равно: Easing.InBack, Easing.OutBack, Easing.InOutBack или Easing.OutInBack.

easing.period применима только если easing.type равно: Easing.InElastic, Easing.OutElastic, Easing.InOutElastic или Easing.OutInElastic.

easing.bezierCurve применима только если easing.type равно: Easing.BezierSpline. Это свойство представляет собой список<вещественное>, содержащий группы из трех точек, определяющих кривую от 0,0 до 1,1 - контрольная точка 1, контрольная точка 2, конечная точка: [cx1, cy1, cx2, cy2, endx, endy, ...]. Последняя точка должна быть 1,1.

См. Кривые смягчения для демонстрации различных настроек смягчения.

exclude : список<Объект>

Это свойство содержит элементы, на которые эта анимация не должна влиять.

См. также PropertyAnimation::targets.

from : значение

Это свойство содержит начальное значение для анимации.

Если PropertyAnimation определен в Transition или Behavior, это значение по умолчанию равно значению, определенному в начальном состоянии Transition, или текущему значению свойства в момент срабатывания Behavior.

См. также Анимации и переходы в Qt Quick.

to : значение

Это свойство содержит конечное значение для анимации.

Если PropertyAnimation определен в рамках Перехода или Поведения, это значение по умолчанию равно значению, определенному в конечном состоянии Перехода, или значению изменения свойства, которое вызвало Поведение.

См. также Анимация и Переходы в Qt Quick.