Тип QML Repeater

Инициализирует несколько компонентов на основе Item, используя предоставленную модель. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• count : int
• delegate : Component
• model : any

Сигналы

• itemAdded(int index, Item item)
• itemRemoved(int index, Item item)

Методы

• Item itemAt(index)

Подробное описание

Тип Repeater используется для создания большого количества похожих элементов. Как и другие типы представлений, Repeater имеет свойство model и delegate: для каждой записи в модели делегат создается в контексте, заполненном данными из модели. Элемент Repeater обычно заключен в тип позиционера, такой как Row или Column, чтобы визуально расположить несколько элементов делегата, созданных Repeater.

Следующий Repeater создает три экземпляра элемента Rectangle внутри Row:

import QtQuick 2.0

Row {
    Repeater {
        model: 3
        Rectangle {
            width: 100; height: 40
            border.width: 1
            color: "yellow"
        }
    }
}

Модель model Repeater может быть любым из поддерживаемых моделей данных. Кроме того, как и делегаты для других представлений, делегат Repeater может получить доступ к своему индексу в Repeater, а также к данным модели, относящимся к делегату. Подробности см. в документации свойства delegate.

Элементы, созданные Repeater, вставляются по порядку в качестве дочерних элементов родителя Repeater. Вставка начинается сразу после позиции повторителя в списке стека его родителя. Это позволяет использовать Repeater внутри макета. Например, элементы следующего Repeater размещаются между красным прямоугольником и синим прямоугольником:

Row {
    Rectangle { width: 10; height: 20; color: "red" }
    Repeater {
        model: 10
        Rectangle { width: 20; height: 20; radius: 10; color: "green" }
    }
    Rectangle { width: 10; height: 20; color: "blue" }
}

Примечание: Элемент Repeater владеет всеми элементами, которые он создает. Удаление или динамическое уничтожение элемента, созданного Repeater, приводит к непредсказуемому поведению.

Рекомендации по использованию Repeater

Тип Repeater создает все свои делегаты сразу при первом создании повторителя. Это может быть неэффективно, если есть большое количество делегатов, и не все они должны быть видны одновременно. В этом случае рассмотрите использование других типов представлений, таких как ListView (который создает делегаты только при прокрутке в область видимости) или использование методов динамического создания объектов для создания элементов по мере необходимости.

Также обратите внимание, что Repeater основан на Item и может повторять только объекты, производные от Item. Например, он не может использоваться для повторения QtObjects:

// bad code:
Item {
    // Can't repeat QtObject as it doesn't derive from Item.
    Repeater {
        model: 10
        QtObject {}
    }
}

Документация свойств

count : int

Это свойство содержит количество элементов в модели.

Примечание: Количество элементов в модели, указанное в свойстве count, может отличаться от количества созданных делегатов, если Repeater в процессе создания делегатов или настроен неправильно.

[по умолчанию] delegate : Component

Делегат предоставляет шаблон, определяющий каждый элемент, созданный повторителем.

Делегатам доступно только для чтения свойство index , которое указывает индекс делегата внутри повторителя. Например, следующий делегат Text отображает индекс каждого повторяющегося элемента:

Column {
    Repeater {
        model: 10
        Text { text: "I'm item " + index }
    }
}

Если model является списком строк или списком объектов, делегат также получает доступ к только для чтения свойству modelData , которое содержит данные строки или объекта. Например:

Column {
    Repeater {
        model: ["apples", "oranges", "pears"]
        Text { text: "Data: " + modelData }
    }
}

Если model является объектом модели (например, ListModel), делегат может получить доступ ко всем ролям модели в виде именованных свойств так же, как и делегаты для таких типов представлений, как ListView.

См. также QML Модели данных.

model : any

Модель, предоставляющая данные для повторителя.

Это свойство может быть установлено на любую из поддерживаемых моделей данных:

• Число, указывающее количество делегатов, которые должен создать повторитель
• Модель (например, элемент ListModel или подкласс QAbstractItemModel)
• Список строк
• Список объектов

Тип модели влияет на свойства, доступные делегату delegate.

См. также Модели данных.

Документация сигналов

itemAdded(int index, Item item)

Этот сигнал излучается, когда элемент добавляется в повторитель. Параметр index содержит индекс, в который был вставлен элемент внутри повторителя, а параметр item содержит добавленный Item.

Примечание: Соответствующий обработчик — onItemAdded.

itemRemoved(int index, Item item)

Этот сигнал излучается, когда элемент удаляется из повторителя. Параметр index содержит индекс, из которого был удален элемент в повторителе, а параметр item содержит удаленный Item.

Не храните ссылку на item, если он был создан этим повторителем, так как в этих случаях он будет удален вскоре после обработки сигнала.

Примечание: Соответствующий обработчик — onItemRemoved.

Документация методов

Item itemAt(index)

Возвращает Item, созданный по заданному индексу, или null, если элемент с индексом отсутствует.