Связывание типа QML

Позволяет произвольно создавать привязки свойств. Подробнее...

• Список всех членов, включая унаследованные члены

Свойства

• delayed : bool
• property : string
• restoreMode : перечисление
• target : Объект
• value : любой
• when : bool

Подробное описание

В QML привязки свойств приводят к зависимости между свойствами разных объектов.

Привязка к недоступному свойству

Иногда необходимо привязать свойство объекта к свойству другого объекта, который не создаётся напрямую в QML, например, свойство класса, экспортированного в QML из C++. Вы можете использовать тип Binding для установления этой зависимости; привязывая любое значение к любому свойству любого объекта.

Например, в приложении C++, отображающем свойство "app.enteredText" в QML, вы можете использовать Binding для обновления свойства enteredText.

TextEdit { id: myTextField; text: "Please type here..." }
Binding { target: app; property: "enteredText"; value: myTextField.text }

Когда text изменяется, свойство C++ enteredText будет обновляться автоматически.

Условные привязки

В некоторых случаях вам может потребоваться изменить значение свойства, когда выполняется определённое условие, но оставить его неизменным в противном случае. Часто это невозможно сделать с прямыми привязками, поскольку вам нужно указать значения для всех возможных ветвей.

Например, фрагмент кода ниже приводит к предупреждению всякий раз, когда вы отпускаете кнопку мыши. Это связано с тем, что значение привязки не определено, когда кнопка мыши не нажата.

// produces warning: "Unable to assign [undefined] to double value"
value: if (mouse.pressed) mouse.mouseX

Тип Binding может предотвратить это предупреждение.

Binding on value {
    when: mouse.pressed
    value: mouse.mouseX
}

Тип Binding восстанавливает любые ранее установленные прямые привязки к свойству.

См. также Qt QML.

Документация по свойствам

[с 5.8] delayed : bool

Это свойство определяет, должна ли привязка быть отложена.

Отложенная привязка не будет немедленно обновлять целевой объект, а подождёт, пока очередь событий не будет очищена. Это может использоваться в качестве оптимизации или для предотвращения назначения промежуточных значений.

Binding {
    target: contactName; property: 'text'
    value: givenName + " " + familyName; when: list.ListView.isCurrentItem
    delayed: true
}

Это свойство было добавлено в Qt 5.8.

property : string

Свойство, которое нужно обновить.

Это может быть групповое свойство, если выражение приводит к обращению к свойству типа значения. Например:

Item {
    id: item

    property rect rectangle: Qt.rect(0, 0, 200, 200)
}

Binding {
    target: item
    property: "rectangle.x"
    value: 100
}

[с 5.14] restoreMode : перечисление

Это свойство может использоваться для описания того, должен ли и как должно восстанавливаться исходное значение при отключении привязки.

Возможные значения:

• Binding.RestoreNone Исходное значение вообще не восстанавливается
• Binding.RestoreBinding Исходное значение восстанавливается, если оно было другой привязкой. В этом случае снова действует старая привязка.
• Binding.RestoreValue Исходное значение восстанавливается, если оно было простым значением, а не привязкой.
• Binding.RestoreBindingOrValue Исходное значение всегда восстанавливается.

Значение по умолчанию Binding.RestoreBindingOrValue.

Если вы полагаетесь на какое-либо конкретное поведение, касающееся восстановления простых значений при отключении привязок, вам следует явно установить restoreMode.

Зависимость от restoreMode, который не восстанавливает предыдущую привязку или значение для определённого свойства, приводит к предупреждению во время выполнения.

Это свойство было добавлено в Qt 5.14.

target : Объект

Объект, который нужно обновить.

value : любой

Значение, которое нужно установить для объекта и свойства цели. Это может быть константа (что не очень полезно) или связанное выражение.

when : bool

Это свойство содержит значение, когда привязка активна. Оно должно быть установлено в выражение, которое вычисляет значение true, когда вы хотите, чтобы привязка была активна.

Binding {
    target: contactName; property: 'text'
    value: name; when: list.ListView.isCurrentItem
}

По умолчанию любая ранее установленная привязка или значение восстанавливаются при деактивации привязки. Вы можете настроить поведение восстановления, используя свойство restoreMode.

См. также restoreMode.