Тип QML Tumbler

Поворачиваемое колесо элементов, которые можно выбрать. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• count : int
• currentIndex : int
• currentItem : Item
• delegate : Component
• model : variant
• moving : bool
• visibleItemCount : int
• wrap : bool

Присоединенные свойства

• displacement : real
• tumbler : Tumbler

Методы

• void positionViewAtIndex(int index, PositionMode mode)

Подробное описание

Tumbler {
    model: 5
    // ...
}

Tumbler позволяет пользователю выбрать вариант из вращающегося "колеса" элементов. Он полезен, когда вариантов слишком много для использования, например, RadioButton, и слишком мало для использования редактируемого SpinBox. Он удобен тем, что не требует использования клавиатуры и перематывается в начало и конец при большом количестве элементов.

API аналогичен представлению данных, как у ListView и PathView; можно задать модель и делегат, а свойства count и currentItem предоставляют только для чтения информацию о представлении. Для позиционирования представления на определенном индексе используйте positionViewAtIndex().

В отличие от представлений, таких как PathView и ListView, всегда есть текущий элемент (если модель не пуста). Это означает, что когда count равен 0, currentIndex будет -1. Во всех остальных случаях он будет больше или равен 0.

По умолчанию Tumbler перематывается в начало и конец, если в модели элементов больше, чем видимых элементов; то есть, когда count больше visibleItemCount:

import QtQuick
import QtQuick.Window
import QtQuick.Controls

Rectangle {
    width: frame.implicitWidth + 10
    height: frame.implicitHeight + 10

    function formatText(count, modelData) {
        var data = count === 12 ? modelData + 1 : modelData;
        return data.toString().length < 2 ? "0" + data : data;
    }

    FontMetrics {
        id: fontMetrics
    }

    Component {
        id: delegateComponent

        Label {
            text: formatText(Tumbler.tumbler.count, modelData)
            opacity: 1.0 - Math.abs(Tumbler.displacement) / (Tumbler.tumbler.visibleItemCount / 2)
            horizontalAlignment: Text.AlignHCenter
            verticalAlignment: Text.AlignVCenter
            font.pixelSize: fontMetrics.font.pixelSize * 1.25
        }
    }

    Frame {
        id: frame
        padding: 0
        anchors.centerIn: parent

        Row {
            id: row

            Tumbler {
                id: hoursTumbler
                model: 12
                delegate: delegateComponent
            }

            Tumbler {
                id: minutesTumbler
                model: 60
                delegate: delegateComponent
            }

            Tumbler {
                id: amPmTumbler
                model: ["AM", "PM"]
                delegate: delegateComponent
            }
        }
    }
}

См. также Настройка Tumbler и Ввод.

Документация по свойствам

[только для чтения] count : int

Это свойство содержит количество элементов в модели.

currentIndex : int

Это свойство содержит индекс текущего элемента.

Значение этого свойства равно -1 когда count равен 0. Во всех остальных случаях оно будет больше или равно 0.

См. также currentItem и positionViewAtIndex().

[только для чтения] currentItem : Item

Это свойство содержит элемент по текущему индексу.

См. также currentIndex и positionViewAtIndex().

delegate : Component

Это свойство содержит делегат, используемый для отображения каждого элемента.

model : variant

Это свойство содержит модель, которая предоставляет данные для этого tumbler.

[с QtQuick.Controls 2.2 (Qt 5.9)] moving : bool

Это свойство описывает, перемещается ли tumbler в данный момент, из-за того, что пользователь перетаскивает или щелкает его.

Это свойство было представлено в QtQuick.Controls 2.2 (Qt 5.9).

visibleItemCount : int

Это свойство содержит количество видимых элементов в tumbler. Оно должно быть нечётным числом, так как текущий элемент всегда находится по вертикали посередине.

[с QtQuick.Controls 2.1 (Qt 5.8)] wrap : bool

Это свойство определяет, будет ли tumbler перематываться в начало или конец.

Значение по умолчанию равно false когда count меньше visibleItemCount, так как взаимодействовать с неперематывающимся Tumbler проще, когда элементов немного. Чтобы переопределить это поведение, явно задайте значение этого свойства. Чтобы вернуться к поведению по умолчанию, установите это свойство в значение undefined.

Это свойство было представлено в QtQuick.Controls 2.1 (Qt 5.8).

Документация по присоединенным свойствам

[только для чтения] Tumbler.displacement : real

Это присоединенное свойство содержит значение от -visibleItemCount / 2 до visibleItemCount / 2, которое представляет, насколько далеко этот элемент находится от текущего элемента, где 0 означает полное соответствие.

Например, элемент будет иметь 40% непрозрачности, когда он не является текущим элементом, и перейдет к 100% непрозрачности, когда станет текущим элементом:

delegate: Text {
    text: modelData
    opacity: 0.4 + Math.max(0, 1 - Math.abs(Tumbler.displacement)) * 0.6
}

[только для чтения] Tumbler.tumbler : Tumbler

Это присоединенное свойство содержит tumbler. Свойство можно привязать к делегату tumbler. Значение равно null если элемент не является делегатом tumbler.

Документация по методам

[since QtQuick.Controls 2.5 (Qt 5.12)] void positionViewAtIndex(int index, PositionMode mode)

Позиционирует представление так, чтобы index находился в позиции, указанной mode.

Например:

positionViewAtIndex(10, Tumbler.Center)

Если wrap true (по умолчанию), доступны режимы функции PathView's positionViewAtIndex(), в противном случае доступны режимы функции ListView's positionViewAtIndex().

Примечание: Существует известное ограничение, что использование Tumbler.Beginning когда wrap true приведет к неправильному позиционированию элемента вверху представления. В качестве обходного решения передайте index - 1.

Этот метод был представлен в QtQuick.Controls 2.5 (Qt 5.12).

См. также currentIndex.