Тип QML Repeater

Создает несколько компонентов на основе Item, используя предоставленную модель. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• count : int
• delegate : Component
• model : any

Сигналы

• itemAdded(int index, Item item)
• itemRemoved(int index, Item item)

Методы

• Item itemAt(index)

Подробное описание

Тип Repeater используется для создания большого количества похожих элементов. Как и другие типы представлений, Repeater имеет свойство model и delegate: для каждой записи в модели делегат создается в контексте, заполненном данными из модели. Элемент Repeater обычно заключен в тип позиционера, например Row или Column, для визуального размещения нескольких элементов делегата, созданных Repeater.

Следующий Repeater создает три экземпляра элемента Rectangle внутри Row:

import QtQuick 2.0

Row {
    Repeater {
        model: 3
        Rectangle {
            width: 100; height: 40
            border.width: 1
            color: "yellow"
        }
    }
}

Модель model Repeater может быть любым из поддерживаемых моделей данных. Кроме того, как и делегаты для других представлений, делегат Repeater может получить свой индекс в пределах Repeater, а также данные модели, относящиеся к делегату. Дополнительные сведения см. в документации по свойству delegate.

Созданные Repeater элементы вставляются в порядке следования в качестве дочерних элементов родителя Repeater. Вставка начинается сразу после позиции повторителя в списке стека родителя. Это позволяет использовать Repeater внутри макета. Например, элементы следующего Repeater размещаются между красным и синим прямоугольниками:

Row {
    Rectangle { width: 10; height: 20; color: "red" }
    Repeater {
        model: 10
        Rectangle { width: 20; height: 20; radius: 10; color: "green" }
    }
    Rectangle { width: 10; height: 20; color: "blue" }
}

Примечание: Элемент Repeater владеет всеми созданными им элементами. Удаление или динамическое уничтожение элемента, созданного Repeater, приводит к непредсказуемому поведению.

Учет при использовании Repeater

Тип Repeater создает все свои элементы делегата при первом создании повторителя. Это может быть неэффективно, если имеется большое количество элементов делегата и не все из них требуются одновременно. В этом случае следует использовать другие типы представлений, такие как ListView (который создает элементы делегата только при прокрутке в область видимости) или использовать методы динамического создания объектов для создания элементов по мере необходимости.

Обратите также внимание, что Repeater основан на Item и может повторять только объекты, производные от Item. Например, его нельзя использовать для повторения QtObjects:

// bad code:
Item {
    // Can't repeat QtObject as it doesn't derive from Item.
    Repeater {
        model: 10
        QtObject {}
    }
}

Документация по свойствам

count : int

Это свойство содержит количество элементов в модели.

Примечание: Количество элементов в модели, сообщённое свойством count, может отличаться от количества созданных делегатов, если Repeater находится в процессе создания делегатов или настроен некорректно.

[по умолчанию] delegate : Component

Делегат предоставляет шаблон, определяющий каждый элемент, созданный повторителем.

Делегатам предоставляется доступ к только для чтения свойству index, которое указывает индекс делегата в пределах повторителя. Например, следующий делегат Text отображает индекс каждого повторяющегося элемента:

Column {
    Repeater {
        model: 10
        Text { text: "I'm item " + index }
    }
}

Если model представляет собой список строк или список объектов, делегату также предоставляется доступ к только для чтения свойству modelData, которое содержит данные строки или объекта. Например:

Column {
    Repeater {
        model: ["apples", "oranges", "pears"]
        Text { text: "Data: " + modelData }
    }
}

Если model — это объект модели (например, ListModel), делегат может получить доступ ко всем ролям модели как к именованным свойствам, так же, как это делают делегаты для таких типов представления, как ListView.

См. также QML Модели данных.

model : any

Модель, предоставляющая данные для повторителя.

Это свойство может принимать любые поддерживаемые модели данных:

• Число, указывающее количество делегатов, которые должен создать повторитель
• Модель (например, элемент ListModel или подкласс QAbstractItemModel)
• Список строк
• Список объектов

Тип модели влияет на свойства, которые доступны для делегата.

См. также Модели данных.

Документация по сигналам

itemAdded(int index, Item item)

Этот сигнал излучается при добавлении элемента в повторитель. Параметр index содержит индекс, в который был вставлен элемент, а параметр item содержит добавленный Item.

Примечание: Соответствующий обработчик — onItemAdded.

itemRemoved(int index, Item item)

Этот сигнал излучается при удалении элемента из повторителя. Параметр index содержит индекс, из которого был удалён элемент, а параметр item содержит удалённый Item.

Не сохраняйте ссылку на item, если он был создан этим повторителем, так как в этих случаях он будет удалён вскоре после обработки сигнала.

Примечание: Соответствующий обработчик — onItemRemoved.

Документация по методам

Item itemAt(index)

Возвращает Item, созданный по заданному индексу, или null, если элемент по индексу отсутствует.