try_compile

• Попытка скомпилировать целые проекты
• Попытка скомпилировать исходные файлы
• Другие параметры поведения
• См. также

Попробуйте собрать некоторый код.

Попытка скомпилировать целые проекты

try_compile(<compileResultVar> PROJECT <projectName>
            SOURCE_DIR <srcdir>
            [BINARY_DIR <bindir>]
            [TARGET <targetName>]
            [LOG_DESCRIPTION <text>]
            [NO_CACHE]
            [NO_LOG]
            [CMAKE_FLAGS <flags>...]
            [OUTPUT_VARIABLE <var>])

Попытайтесь собрать проект. Успешное завершение сборки возвращает TRUE , а неудачная - FALSE в <compileResultVar>.

В этом формате <srcdir> должен содержать полный проект CMake с файлом CMakeLists.txt и всеми исходными файлами. Файлы <bindir> и <srcdir> не будут удалены после выполнения этой команды. Укажите <targetName> , чтобы собрать определённую цель вместо цели all или ALL_BUILD. Значение других параметров см. ниже.

Эта команда поддерживает альтернативную подпись для CMake, более старого, чем 3.25. Рекомендуется использовать вышеприведенную подпись для ясности.

try_compile(<compileResultVar> <bindir> <srcdir>
            <projectName> [<targetName>]
            [CMAKE_FLAGS <flags>...]
            [OUTPUT_VARIABLE <var>])

Попытка скомпилировать исходные файлы

try_compile(<compileResultVar>
            <SOURCES <srcfile...>                 |
             SOURCE_FROM_CONTENT <name> <content> |
             SOURCE_FROM_VAR <name> <var>         |
             SOURCE_FROM_FILE <name> <path>       >...
            [LOG_DESCRIPTION <text>]
            [NO_CACHE]
            [NO_LOG]
            [CMAKE_FLAGS <flags>...]
            [COMPILE_DEFINITIONS <defs>...]
            [LINK_OPTIONS <options>...]
            [LINK_LIBRARIES <libs>...]
            [OUTPUT_VARIABLE <var>]
            [COPY_FILE <fileName> [COPY_FILE_ERROR <var>]]
            [<LANG>_STANDARD <std>]
            [<LANG>_STANDARD_REQUIRED <bool>]
            [<LANG>_EXTENSIONS <bool>]
            )

Попробуйте собрать исполняемый файл или статическую библиотеку из одного или нескольких исходных файлов (какой — определяется переменной CMAKE_TRY_COMPILE_TARGET_TYPE). Успешное завершение сборки возвращает TRUE, а неудачное — FALSE в <compileResultVar>.

В этом формате необходимо указать один или несколько исходных файлов. Кроме того, один из SOURCES и/или SOURCE_FROM_* должен предшествовать другим ключевым словам.

Если CMAKE_TRY_COMPILE_TARGET_TYPE не задано или равно EXECUTABLE, исходные файлы должны включать определение для main, и CMake создаст файл CMakeLists.txt для сборки исходных файлов как исполняемого файла. Если CMAKE_TRY_COMPILE_TARGET_TYPE установлено в STATIC_LIBRARY, вместо этого будет построена статическая библиотека, и определение для main не требуется. Для исполняемого файла сгенерированный файл CMakeLists.txt будет содержать что-то вроде следующего:

add_definitions(<expanded COMPILE_DEFINITIONS from caller>)
include_directories(${INCLUDE_DIRECTORIES})
link_directories(${LINK_DIRECTORIES})
add_executable(cmTryCompileExec <srcfile>...)
target_link_options(cmTryCompileExec PRIVATE <LINK_OPTIONS from caller>)
target_link_libraries(cmTryCompileExec ${LINK_LIBRARIES})

CMake автоматически создаёт для каждой операции try_compile уникальную директорию в ${CMAKE_BINARY_DIR}/CMakeFiles/CMakeScratch с неопределённым именем. Эти директории очищаются автоматически, если не указан параметр --debug-trycompile для cmake. Также такие директории из предыдущих запусков безусловно очищаются в начале любого выполнения cmake.

Эта команда поддерживает альтернативную подпись для CMake, более старого, чем 3.25. Рекомендуется использовать вышеприведенную подпись для ясности.

try_compile(<compileResultVar> <bindir> <srcfile|SOURCES srcfile...>
            [CMAKE_FLAGS <flags>...]
            [COMPILE_DEFINITIONS <defs>...]
            [LINK_OPTIONS <options>...]
            [LINK_LIBRARIES <libs>...]
            [OUTPUT_VARIABLE <var>]
            [COPY_FILE <fileName> [COPY_FILE_ERROR <var>]]
            [<LANG>_STANDARD <std>]
            [<LANG>_STANDARD_REQUIRED <bool>]
            [<LANG>_EXTENSIONS <bool>]
            )

В этой версии try_compile будет использовать <bindir>/CMakeFiles/CMakeTmp для своей работы, и все такие файлы будут автоматически очищены. Для отладки параметр --debug-trycompile можно передать в cmake, чтобы избежать этой очистки. Однако несколько последовательных операций try_compile, если заданы с одинаковым <bindir>, будут повторно использовать эту единственную выходную директорию, так что вы можете отладить только один такой вызов try_compile за раз. Использование новой подписи рекомендуется для упрощения отладки нескольких операций try_compile.

Параметры:

CMAKE_FLAGS <flags>...

Укажите флаги в формате -DVAR:TYPE=VALUE, которые будут переданы в командную строку cmake(1), используемую для запуска тестового сборки. Приведенный пример демонстрирует использование значений для переменных INCLUDE_DIRECTORIES, LINK_DIRECTORIES, и LINK_LIBRARIES.

COMPILE_DEFINITIONS <defs>...

Укажите аргументы -Ddefinition для передачи в add_definitions() в сгенерированном тестовом проекте.

COPY_FILE <fileName>

Скопировать созданный исполняемый файл или статическую библиотеку в указанный <fileName>.

COPY_FILE_ERROR <var>

Используется после COPY_FILE для записи в переменную <var> любого сообщения об ошибке, возникшей при попытке копирования файла.

LINK_LIBRARIES <libs>...

Укажите библиотеки, которые необходимо подключить в сгенерированном проекте. Список библиотек может ссылаться на системные библиотеки и на Импортированные целевые объекты из вызывающего проекта.

Если этот параметр указан, любые значения -DLINK_LIBRARIES=... для параметра CMAKE_FLAGS будут проигнорированы.

LINK_OPTIONS <options>...

Добавлено в версии 3.14.

Укажите параметры этапа линковки для передачи в target_link_options() или для установки свойства целевого объекта STATIC_LIBRARY_OPTIONS в сгенерированном проекте, в зависимости от переменной CMAKE_TRY_COMPILE_TARGET_TYPE.

LOG_DESCRIPTION <text>

Добавлено в версии 3.26.

Укажите непустое текстовое описание цели проверки. Это записывается в запись cmake-configure-log(7).

NO_CACHE

Добавлено в версии 3.25.

Результат будет сохранен в обычной переменной, а не в записи кэша.

Переменная результата обычно кэшируется, чтобы можно было использовать простой шаблон для избежания повторного выполнения теста при последующих запусках CMake:

if(NOT DEFINED RESULTVAR)
  # ...(check-specific setup code)...
  try_compile(RESULTVAR ...)
  # ...(check-specific logging and cleanup code)...
endif()

Если переменная защиты и переменная результата не совпадают (например, если тест является частью более крупного анализа), NO_CACHE может быть полезно для предотвращения утечки промежуточной переменной результата в кэш.

NO_LOG

Добавлено в версии 3.26.

Не записывать запись cmake-configure-log(7) для этого вызова.

OUTPUT_VARIABLE <var>

Сохранить вывод процесса сборки в указанную переменную.

SOURCE_FROM_CONTENT <name> <content>

Добавлено в версии 3.25.

Записать <content> в файл с именем <name> в каталоге операции. Это может быть использовано для того, чтобы избежать необходимости отдельно записывать исходный файл, когда содержимое файла динамически задано. Указанное <name> не должно содержать компонентов пути.

SOURCE_FROM_CONTENT может быть указано несколько раз.

SOURCE_FROM_FILE <name> <path>

Добавлено в версии 3.25.

Скопировать <path> в файл с именем <name> в каталоге операции. Это можно использовать для объединения файлов в каталог операций, что может быть полезно, если исходный файл, который уже существует (то есть, как отдельный файл в репозитории исходного кода проекта), должен ссылаться на другие файлы, созданные SOURCE_FROM_*. (В противном случае, SOURCES обычно более удобно.) Указанное <name> не должно содержать компонентов пути.

SOURCE_FROM_VAR <name> <var>

Добавлено в версии 3.25.

Записать содержимое <var> в файл с именем <name> в каталоге операций. Это то же, что и SOURCE_FROM_CONTENT, но берет содержимое из указанной переменной CMake, а не непосредственно, что может быть полезно при передаче аргументов через функцию, которая оборачивает try_compile. Указанное <name> не должно содержать компонентов пути.

SOURCE_FROM_VAR может быть указано несколько раз.

<LANG>_STANDARD <std>

Добавлено в версии 3.8.

Укажите свойство целевого объекта C_STANDARD, CXX_STANDARD, OBJC_STANDARD, OBJCXX_STANDARD или CUDA_STANDARD сгенерированного проекта.

<LANG>_STANDARD_REQUIRED <bool>

Добавлено в версии 3.8.

Укажите свойство целевого объекта C_STANDARD_REQUIRED, CXX_STANDARD_REQUIRED, OBJC_STANDARD_REQUIRED, OBJCXX_STANDARD_REQUIRED или CUDA_STANDARD_REQUIRED сгенерированного проекта.

<LANG>_EXTENSIONS <bool>

Добавлено в версии 3.8.

Укажите свойство целевого объекта C_EXTENSIONS, CXX_EXTENSIONS, OBJC_EXTENSIONS, OBJCXX_EXTENSIONS или CUDA_EXTENSIONS сгенерированного проекта.

Другие настройки поведения

Текущие настройки CMP0065 и CMP0083 распространяются на сгенерированный тестовый проект.

Установите переменную CMAKE_TRY_COMPILE_CONFIGURATION для выбора конфигурации сборки:

• Для генераторов с несколькими конфигурациями это выбирает конфигурацию, которую следует собрать.
• Для генераторов с одной конфигурацией это устанавливает CMAKE_BUILD_TYPE в тестовом проекте.

См. также

• try_run()