Collectable протокол

Протокол для обхода структур данных.

Функция Enum.into/2 использует этот протокол для вставки перечислимого объекта в коллекцию:

iex> Enum.into([a: 1, b: 2], %{})
%{a: 1, b: 2}

Почему Collectable?

Протокол Enumerable полезен для извлечения значений из коллекции. Для поддержки широкого диапазона значений функции, предоставляемые протоколом Enumerable, не сохраняют форму. Например, передача карты в Enum.map/2 всегда возвращает список.

Этот дизайн преднамеренный. Enumerable был разработан для поддержки бесконечных коллекций, ресурсов и других структур с фиксированной формой. Например, нет смысла вставлять значения в Range, так как у него фиксированная форма, где хранятся только пределы диапазона и шаг.

Модуль Collectable был разработан для заполнения пробела, оставленного протоколом Enumerable. Collectable.into/1 можно рассматривать как противоположность Enumerable.reduce/3. Если функции в Enumerable связаны с извлечением значений, то Collectable.into/1 связана с сбором этих значений в структуру.

Примеры

Чтобы показать, как вручную использовать протокол Collectable, давайте поиграем с упрощенной реализацией для MapSet.

iex> {initial_acc, collector_fun} = Collectable.into(MapSet.new())
iex> updated_acc = Enum.reduce([1, 2, 3], initial_acc, fn elem, acc ->
...>   collector_fun.(acc, {:cont, elem})
...> end)
iex> collector_fun.(updated_acc, :done)
MapSet.new([1, 2, 3])

Чтобы продемонстрировать, как можно реализовать протокол, мы снова можем взглянуть на упрощенную реализацию для MapSet. В этой реализации "сбор" элементов просто означает вставку их в множество через MapSet.put/2.

defimpl Collectable, for: MapSet do
  def into(map_set) do
    collector_fun = fn
      map_set_acc, {:cont, elem} ->
        MapSet.put(map_set_acc, elem)

      map_set_acc, :done ->
        map_set_acc

      _map_set_acc, :halt ->
        :ok
    end

    initial_acc = map_set

    {initial_acc, collector_fun}
  end
end

Теперь мы можем вызвать Enum.into/2:

iex> Enum.into([1, 2, 3], MapSet.new())
MapSet.new([1, 2, 3])