Data.Foldable

class Foldable t where Source

Структуры данных, которые могут быть свёрнуты.

Например, задан тип данных

data Tree a = Empty | Leaf a | Node (Tree a) a (Tree a)

соответствующий экземпляр будет

instance Foldable Tree where
   foldMap f Empty = mempty
   foldMap f (Leaf x) = f x
   foldMap f (Node l k r) = foldMap f l `mappend` f k `mappend` foldMap f r

Это подходит даже для абстрактных типов, так как предполагается, что моноид удовлетворяет законам моноида. В качестве альтернативы можно определить foldr:

instance Foldable Tree where
   foldr f z Empty = z
   foldr f z (Leaf x) = f x z
   foldr f z (Node l k r) = foldr f (f k (foldr f z r)) l

Foldable экземпляры должны удовлетворять следующим законам:

foldr f z t = appEndo (foldMap (Endo . f) t ) z

foldl f z t = appEndo (getDual (foldMap (Dual . Endo . flip f) t)) z

fold = foldMap id

length = getSum . foldMap (Sum . const  1)

sum, product, maximum, и minimum должны быть в сущности эквивалентны foldMap формам, таким как

sum = getSum . foldMap Sum

но могут быть менее определёнными.

Если тип также является экземпляром Functor , он должен удовлетворять

foldMap f = fold . fmap f

что подразумевает, что

foldMap f . fmap g = foldMap (f . g)

foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)

foldr f z = foldr f z . toList

foldl f z [x1, x2, ..., xn] == (...((z `f` x1) `f` x2) `f`...) `f` xn

foldl f z = foldl f z . toList

foldl' f z = foldl' f z . toList

foldr1 f = foldr1 f . toList

foldl1 f = foldl1 f . toList

foldrM :: (Foldable t, Monad m) => (a -> b -> m b) -> b -> t a -> m b Источник

Монадная свертка над элементами структуры, ассоциирующаяся справа, т. е. справа налево.

foldlM :: (Foldable t, Monad m) => (b -> a -> m b) -> b -> t a -> m b Источник

Монадная свертка над элементами структуры, ассоциирующаяся слева, т. е. слева направо.

traverse_ :: (Foldable t, Applicative f) => (a -> f b) -> t a -> f () Источник

Применяет к каждому элементу структуры действие, вычисляет эти действия слева направо и игнорирует результаты. Для версии, которая не игнорирует результаты, см. traverse.

for_ :: (Foldable t, Applicative f) => t a -> (a -> f b) -> f () Источник

for_ это traverse_ с переставленными аргументами. Для версии, которая не игнорирует результаты, см. for.

>>> for_ [1..4] print
1
2
3
4

sequenceA_ :: (Foldable t, Applicative f) => t (f a) -> f () Источник

Вычисляет каждое действие в структуре слева направо и игнорирует результаты. Для версии, которая не игнорирует результаты, см. sequenceA.

asum :: (Foldable t, Alternative f) => t (f a) -> f a Источник

Сумма коллекции действий, обобщающая concat.

>>> asum [Just "Hello", Nothing, Just "World"]
Just "Hello"

mapM_ :: (Foldable t, Monad m) => (a -> m b) -> t a -> m () Источник

Применяет к каждому элементу структуры монадическое действие, вычисляет эти действия слева направо и игнорирует результаты. Для версии, которая не игнорирует результаты, см. mapM.

Начиная с версии base 4.8.0.0, mapM_ это просто traverse_, специализированная для Monad.

forM_ :: (Foldable t, Monad m) => t a -> (a -> m b) -> m () Источник

forM_ это mapM_ с переставленными аргументами. Для версии, которая не игнорирует результаты, см. forM.

Начиная с версии base 4.8.0.0, forM_ это просто for_, специализированная для Monad.

sequence_ :: (Foldable t, Monad m) => t (m a) -> m () Источник

Вычислить каждый монадический оператор в структуре слева направо и проигнорировать результаты. Для версии, которая не игнорирует результаты, см. sequence.

Начиная с версии base 4.8.0.0, sequence_ просто sequenceA_, специализированный для Monad.

msum :: (Foldable t, MonadPlus m) => t (m a) -> m a Source

Сумма набора операций, обобщающая concat. Начиная с версии base 4.8.0.0, msum просто asum, специализированный для MonadPlus.

concat :: Foldable t => t [a] -> [a] Source

Конкатенация всех элементов контейнера списков.

concatMap :: Foldable t => (a -> [b]) -> t a -> [b] Source

Применить функцию ко всем элементам контейнера и конкатенировать полученные списки.

and :: Foldable t => t Bool -> Bool Source

and возвращает конъюнкцию контейнера значений типа Bool. Для получения результата True, контейнер должен быть конечным; False, однако, результат получается из значения False на конечном расстоянии слева.

or :: Foldable t => t Bool -> Bool Source

or возвращает дизъюнкцию контейнера значений типа Bool. Для получения результата False, контейнер должен быть конечным; True, однако, результат получается из значения True на конечном расстоянии слева.

any :: Foldable t => (a -> Bool) -> t a -> Bool Source

Определяет, удовлетворяет ли какой-либо элемент структуры предикату.

all :: Foldable t => (a -> Bool) -> t a -> Bool Source

Определяет, удовлетворяют ли все элементы структуры предикату.

maximumBy :: Foldable t => (a -> a -> Ordering) -> t a -> a Source

Наибольший элемент непустой структуры относительно заданной функции сравнения.

minimumBy :: Foldable t => (a -> a -> Ordering) -> t a -> a Source

Наименьший элемент непустой структуры относительно заданной функции сравнения.

notElem :: (Foldable t, Eq a) => a -> t a -> Bool infix 4 Source

notElem — это отрицание elem.

find :: Foldable t => (a -> Bool) -> t a -> Maybe a Source

Функция find принимает предикат и структуру и возвращает самый левый элемент структуры, соответствующий предикату, или Nothing, если такого элемента нет.