Data.Either

Тип Either String Int — это тип значений, которые могут быть либо String, либо Int. Конструктор Left может быть использован только с String, а конструктор Right — только с Int:

>>> let s = Left "foo" :: Either String Int
>>> s
Left "foo"
>>> let n = Right 3 :: Either String Int
>>> n
Right 3
>>> :type s
s :: Either String Int
>>> :type n
n :: Either String Int

Функция fmap из нашего экземпляра Functor проигнорирует значения Left, но применит заданную функцию к значениям, содержащимся в Right:

>>> let s = Left "foo" :: Either String Int
>>> let n = Right 3 :: Either String Int
>>> fmap (*2) s
Left "foo"
>>> fmap (*2) n
Right 6

Экземпляр Monad для Either позволяет нам объединить несколько действий, которые могут завершиться ошибкой, и завершить работу с ошибкой, если любое из отдельных шагов завершилось ошибкой. Сначала напишем функцию, которая может либо разобрать Int из Char, либо завершиться ошибкой.

>>> import Data.Char ( digitToInt, isDigit )
>>> :{
    let parseEither :: Char -> Either String Int
        parseEither c
          | isDigit c = Right (digitToInt c)
          | otherwise = Left "parse error"
>>> :}

Следующее должно сработать, так как как '1' и '2' могут быть обработаны как Int.

>>> :{
    let parseMultiple :: Either String Int
        parseMultiple = do
          x <- parseEither '1'
          y <- parseEither '2'
          return (x + y)
>>> :}

>>> parseMultiple
Right 3

Но следующее должно завершиться ошибкой, так как первое действие, в котором мы пытаемся разобрать 'm' как Int завершится ошибкой:

>>> :{
    let parseMultiple :: Either String Int
        parseMultiple = do
          x <- parseEither 'm'
          y <- parseEither '2'
          return (x + y)
>>> :}

>>> parseMultiple
Left "parse error"

Создаём два значения типа Either String Int, одно с использованием конструктора Left, а другое — с Right. Затем применяем функцию «either» к функции length (если у нас String) или функции «удваивания» (если у нас Int):

>>> let s = Left "foo" :: Either String Int
>>> let n = Right 3 :: Either String Int
>>> either length (*2) s
3
>>> either length (*2) n
6

Базовое использование:

>>> let list = [ Left "foo", Right 3, Left "bar", Right 7, Left "baz" ]
>>> lefts list
["foo","bar","baz"]

Базовое использование:

>>> let list = [ Left "foo", Right 3, Left "bar", Right 7, Left "baz" ]
>>> rights list
[3,7]

Базовое использование:

>>> isLeft (Left "foo")
True
>>> isLeft (Right 3)
False

Предполагая, что значение Left обозначает некоторую ошибку, мы можем использовать isLeft для написания очень простой функции обработки ошибок, которая ничего не делает в случае успеха и выводит «ОШИБКА», если произошла ошибка.

Этот пример демонстрирует, как isLeft может быть использован для избежания сопоставления с образцом, когда значение, содержащееся в конструкторе, не интересует:

>>> import Control.Monad ( when )
>>> let report e = when (isLeft e) $ putStrLn "ERROR"
>>> report (Right 1)
>>> report (Left "parse error")
ERROR

Базовое использование:

>>> isRight (Left "foo")
False
>>> isRight (Right 3)
True

Предполагая, что значение Left обозначает некоторую ошибку, мы можем использовать isRight для написания очень простой функции отображения, которая выводит только «УСПЕХ», когда вычисление выполнено успешно.

Этот пример демонстрирует, как isRight может быть использован для избежания сопоставления с образцом, когда значение, содержащееся в конструкторе, не интересует:

>>> import Control.Monad ( when )
>>> let report e = when (isRight e) $ putStrLn "SUCCESS"
>>> report (Left "parse error")
>>> report (Right 1)
SUCCESS

Базовое использование:

>>> fromLeft 1 (Left 3)
3
>>> fromLeft 1 (Right "foo")
1

Базовое использование:

>>> fromRight 1 (Right 3)
3
>>> fromRight 1 (Left "foo")
1

Базовое использование:

>>> let list = [ Left "foo", Right 3, Left "bar", Right 7, Left "baz" ]
>>> partitionEithers list
(["foo","bar","baz"],[3,7])

Пара, возвращаемая partitionEithers x, должна быть такой же, как у (lefts x, rights x):

>>> let list = [ Left "foo", Right 3, Left "bar", Right 7, Left "baz" ]
>>> partitionEithers list == (lefts list, rights list)
True