Data.Either

Тип Either String Int — это тип значений, которые могут быть либо String или Int. Конструктор Left может использоваться только с String, а конструктор Right может использоваться только с Int:

>>> let s = Left "foo" :: Either String Int
>>> s
Left "foo"
>>> let n = Right 3 :: Either String Int
>>> n
Right 3
>>> :type s
s :: Either String Int
>>> :type n
n :: Either String Int

Функция fmap из нашего экземпляра Functor проигнорирует Left значения, но применит предоставленную функцию к значениям, содержащимся в Right:

>>> let s = Left "foo" :: Either String Int
>>> let n = Right 3 :: Either String Int
>>> fmap (*2) s
Left "foo"
>>> fmap (*2) n
Right 6

Экземпляр Monad для Either позволяет нам объединить несколько действий, которые могут завершиться ошибкой, и завершиться ошибкой в целом, если любое из отдельных шагов завершилось ошибкой. Сначала мы напишем функцию, которая может либо разобрать Int из Char, или завершиться ошибкой.

>>> import Data.Char ( digitToInt, isDigit )
>>> :{
    let parseEither :: Char -> Either String Int
        parseEither c
          | isDigit c = Right (digitToInt c)
          | otherwise = Left "parse error"
>>> :}

Следующее должно работать, поскольку как '1' так и '2' могут быть распарсены как Int.

>>> :{
    let parseMultiple :: Either String Int
        parseMultiple = do
          x <- parseEither '1'
          y <- parseEither '2'
          return (x + y)
>>> :}

>>> parseMultiple
Right 3

Но следующее должно завершиться ошибкой, поскольку первое действие, в котором мы пытаемся разобрать 'm' как Int завершится ошибкой:

>>> :{
    let parseMultiple :: Either String Int
        parseMultiple = do
          x <- parseEither 'm'
          y <- parseEither '2'
          return (x + y)
>>> :}

>>> parseMultiple
Left "parse error"

Мы создаём два значения типа Either String Int, одно с помощью конструктора Left, а другое с помощью конструктора Right. Затем мы применяем функцию «either» к функции length (если у нас есть String) или функции «умножить на два» (если у нас есть Int):

>>> let s = Left "foo" :: Either String Int
>>> let n = Right 3 :: Either String Int
>>> either length (*2) s
3
>>> either length (*2) n
6

Базовое использование:

>>> let list = [ Left "foo", Right 3, Left "bar", Right 7, Left "baz" ]
>>> lefts list
["foo","bar","baz"]

Базовое использование:

>>> let list = [ Left "foo", Right 3, Left "bar", Right 7, Left "baz" ]
>>> rights list
[3,7]

Базовое использование:

>>> isLeft (Left "foo")
True
>>> isLeft (Right 3)
False

Предполагая, что значение Left обозначает какую-либо ошибку, мы можем использовать isLeft для написания очень простой функции отчётности об ошибках, которая ничего не делает в случае успеха и выводит «ERROR», если произошла какая-либо ошибка.

Этот пример демонстрирует, как isLeft можно использовать, чтобы избежать сопоставления с образцом, когда пользователя не интересует значение, содержащееся в конструкторе:

>>> import Control.Monad ( when )
>>> let report e = when (isLeft e) $ putStrLn "ERROR"
>>> report (Right 1)
>>> report (Left "parse error")
ERROR

Базовое использование:

>>> isRight (Left "foo")
False
>>> isRight (Right 3)
True

Предполагая, что значение Left обозначает какую-либо ошибку, мы можем использовать isRight для написания очень простой функции отчётности, которая выводит только «SUCCESS», когда вычисление прошло успешно.

Этот пример демонстрирует, как isRight можно использовать, чтобы избежать сопоставления с образцом, когда пользователя не интересует значение, содержащееся в конструкторе:

>>> import Control.Monad ( when )
>>> let report e = when (isRight e) $ putStrLn "SUCCESS"
>>> report (Left "parse error")
>>> report (Right 1)
SUCCESS

Базовое использование:

>>> fromLeft 1 (Left 3)
3
>>> fromLeft 1 (Right "foo")
1

Основное использование:

>>> fromRight 1 (Right 3)
3
>>> fromRight 1 (Left "foo")
1

Основное использование:

>>> let list = [ Left "foo", Right 3, Left "bar", Right 7, Left "baz" ]
>>> partitionEithers list
(["foo","bar","baz"],[3,7])

Возвращаемая пара partitionEithers x должна быть такой же, как и (lefts x, rights x):

>>> let list = [ Left "foo", Right 3, Left "bar", Right 7, Left "baz" ]
>>> partitionEithers list == (lefts list, rights list)
True