Data.Either

Тип Either String Int — это тип значений, которые могут быть либо String, либо Int. Конструктор Left можно использовать только для String, а конструктор Right — только для Int:

>>> let s = Left "foo" :: Either String Int
>>> s
Left "foo"
>>> let n = Right 3 :: Either String Int
>>> n
Right 3
>>> :type s
s :: Either String Int
>>> :type n
n :: Either String Int

fmap из нашего экземпляра Functor будет игнорировать значения Left, но применит переданную функцию к значениям, содержащимся в Right:

>>> let s = Left "foo" :: Either String Int
>>> let n = Right 3 :: Either String Int
>>> fmap (*2) s
Left "foo"
>>> fmap (*2) n
Right 6

Экземпляр Monad для Either позволяет объединить в цепочку несколько действий, каждое из которых может завершиться неудачей; вся цепочка завершится неудачей, если не удалось выполнить хотя бы один шаг. Сначала напишем функцию, которая может либо разобрать Int из Char, либо завершиться неудачей.

>>> import Data.Char ( digitToInt, isDigit )
>>> :{
    let parseEither :: Char -> Either String Int
        parseEither c
          | isDigit c = Right (digitToInt c)
          | otherwise = Left "parse error"
>>> :}

Следующий пример должен работать, поскольку и '1', и '2' можно разобрать как Int:

>>> :{
    let parseMultiple :: Either String Int
        parseMultiple = do
          x <- parseEither '1'
          y <- parseEither '2'
          return (x + y)
>>> :}

>>> parseMultiple
Right 3

Однако следующий пример должен завершиться неудачей, поскольку первая операция, в которой мы пытаемся разобрать 'm' как Int, завершится неудачей:

>>> :{
    let parseMultiple :: Either String Int
        parseMultiple = do
          x <- parseEither 'm'
          y <- parseEither '2'
          return (x + y)
>>> :}

>>> parseMultiple
Left "parse error"

Создадим два значения типа Either String Int: одно с помощью конструктора Left, а другое — с помощью конструктора Right. Затем применим «либо» функцию length (если у нас есть String), либо функцию «умножить на два» (если у нас есть Int):

>>> let s = Left "foo" :: Either String Int
>>> let n = Right 3 :: Either String Int
>>> either length (*2) s
3
>>> either length (*2) n
6

Пример использования:

>>> let list = [ Left "foo", Right 3, Left "bar", Right 7, Left "baz" ]
>>> lefts list
["foo","bar","baz"]

Пример использования:

>>> let list = [ Left "foo", Right 3, Left "bar", Right 7, Left "baz" ]
>>> rights list
[3,7]

Пример использования:

>>> isLeft (Left "foo")
True
>>> isLeft (Right 3)
False

Предположим, что значение Left обозначает ошибку. Тогда с помощью isLeft можно написать очень простую функцию обработки ошибок, которая ничего не делает в случае успеха и выводит «ОШИБКА», если произошла ошибка.

В этом примере показано, как можно использовать isLeft, чтобы избежать сопоставления с образцом, когда нас не интересует значение, содержащееся в конструкторе:

>>> import Control.Monad ( when )
>>> let report e = when (isLeft e) $ putStrLn "ERROR"
>>> report (Right 1)
>>> report (Left "parse error")
ERROR

Пример использования:

>>> isRight (Left "foo")
False
>>> isRight (Right 3)
True

Предположим, что значение Left обозначает ошибку. Тогда с помощью isRight можно написать очень простую функцию отчёта, которая выводит «УСПЕХ» только в случае успешного выполнения вычисления.

В этом примере показано, как можно использовать isRight, чтобы избежать сопоставления с образцом, когда нас не интересует значение, содержащееся в конструкторе:

>>> import Control.Monad ( when )
>>> let report e = when (isRight e) $ putStrLn "SUCCESS"
>>> report (Left "parse error")
>>> report (Right 1)
SUCCESS

Пример использования:

>>> fromLeft 1 (Left 3)
3
>>> fromLeft 1 (Right "foo")
1

Пример использования:

>>> fromRight 1 (Right 3)
3
>>> fromRight 1 (Left "foo")
1

Пример использования:

>>> let list = [ Left "foo", Right 3, Left "bar", Right 7, Left "baz" ]
>>> partitionEithers list
(["foo","bar","baz"],[3,7])

Пара, возвращённая partitionEithers x, должна совпадать с парой (lefts x, rights x):

>>> let list = [ Left "foo", Right 3, Left "bar", Right 7, Left "baz" ]
>>> partitionEithers list == (lefts list, rights list)
True