Тип QML Flipable

Предоставляет поверхность, которая может быть перевернута. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• back : Элемент
• front : Элемент
• сторона : перечисление

Подробное описание

Flipable — это элемент, который может визуально «переворачиваться» между передней и задней сторонами, как карта. Он может использоваться совместно с Rotation, Состояние и Переходом для создания эффекта переворачивания.

Свойства front и back используются для хранения элементов, которые отображаются соответственно на передней и задней сторонах элемента flipable.

Пример использования

Следующий пример показывает элемент Flipable, который переворачивается всякий раз, когда он нажимается, вращаясь вокруг оси y.

У этого элемента flipable есть свойство flipped типа boolean, которое переключается всякий раз, когда нажимается MouseArea внутри flipable. Когда flipped имеет значение true, элемент переходит в состояние «back»; в этом состоянии значение angle элемента Rotation изменяется на 180 градусов для создания эффекта переворачивания. Когда flipped имеет значение false, элемент возвращается в исходное состояние, в котором значение angle равно 0.

import QtQuick 2.0

Flipable {
    id: flipable
    width: 240
    height: 240

    property bool flipped: false

    front: Image { source: "front.png"; anchors.centerIn: parent }
    back: Image { source: "back.png"; anchors.centerIn: parent }

    transform: Rotation {
        id: rotation
        origin.x: flipable.width/2
        origin.y: flipable.height/2
        axis.x: 0; axis.y: 1; axis.z: 0     // set axis.y to 1 to rotate around y-axis
        angle: 0    // the default angle
    }

    states: State {
        name: "back"
        PropertyChanges { target: rotation; angle: 180 }
        when: flipable.flipped
    }

    transitions: Transition {
        NumberAnimation { target: rotation; property: "angle"; duration: 4000 }
    }

    MouseArea {
        anchors.fill: parent
        onClicked: flipable.flipped = !flipable.flipped
    }
}

Переход Transition создаёт анимацию, изменяющую угол за четыре секунды. Когда элемент переключается между состояниями «back» и исходным, NumberAnimation анимирует угол между его старым и новым значениями.

Подробную информацию о состояниях и исходном состоянии см. в разделе Состояния Qt Quick, а о работе анимаций в рамках переходов см. в разделе Анимация и переходы в Qt Quick.

См. также Примеры пользовательских элементов интерфейса: Flipable.

Документация свойств

Передняя и задняя стороны flipable.

сторона : перечисление

Сторона Flipable, которая в данный момент видна. Возможные значения — Flipable.Front и Flipable.Back.