Тип QML SmoothedAnimation

Позволяет свойству плавно отслеживать значение. Подробнее...

• Список всех членов, включая наследуемые

Свойства

• duration : int
• maximumEasingTime : int
• reversingMode : перечисление
• velocity : real

Подробное описание

SmoothedAnimation анимирует значение свойства до заданного целевого значения, используя кривую сглаживания «ease in/out quad». Когда целевое значение изменяется, кривые сглаживания, используемые для анимации между старым и новым целевыми значениями, плавно соединяются, чтобы создать плавное движение к новому целевому значению, сохраняя текущую скорость.

Следующий пример демонстрирует, как один Rectangle отслеживает положение другого с помощью SmoothedAnimation. Значения x и y зеленого прямоугольника связаны со значениями красного прямоугольника. Всякий раз, когда эти значения изменяются, зеленый прямоугольник плавно анимируется в новое положение:

import QtQuick 2.0

Rectangle {
    width: 800; height: 600
    color: "blue"

    Rectangle {
        width: 60; height: 60
        x: rect1.x - 5; y: rect1.y - 5
        color: "green"

        Behavior on x { SmoothedAnimation { velocity: 200 } }
        Behavior on y { SmoothedAnimation { velocity: 200 } }
    }

    Rectangle {
        id: rect1
        width: 50; height: 50
        color: "red"
    }

    focus: true
    Keys.onRightPressed: rect1.x = rect1.x + 100
    Keys.onLeftPressed: rect1.x = rect1.x - 100
    Keys.onUpPressed: rect1.y = rect1.y - 100
    Keys.onDownPressed: rect1.y = rect1.y + 100
}

SmoothedAnimation можно настроить, задав скорость velocity анимации или продолжительность duration. Если заданы и скорость, и продолжительность, для каждого изменения целевого значения выбирается та, которая приводит к более быстрой анимации.

Например, анимация от 0 до 800 займёт 4 секунды, если задана скорость 200, 8 секунд при продолжительности 8000 и 4 секунды при заданных скорости 200 и продолжительности 8000. Анимация от 0 до 20000 займет 10 секунд при скорости 200, 8 секунд при продолжительности 8000 и 8 секунд при заданных скорости 200 и продолжительности 8000.

По умолчанию скорость SmoothedAnimation составляет 200 единиц/секунду. Обратите внимание, что если диапазон анимируемого значения небольшой, то скорость необходимо соответствующим образом настроить. Например, непрозрачность элемента изменяется от 0 до 1,0. Для обеспечения плавной анимации в этом диапазоне скорость должна быть установлена в значение, например, 0,5 единиц/секунды. Анимация от 0 до 1,0 со скоростью 0,5 займет 2000 мс.

Как и любой другой тип анимации, SmoothedAnimation можно применять различными способами, включая переходы, поведения и источники значений свойств. В документации Анимация и переходы в Qt Quick показаны различные методы создания анимаций.

См. также SpringAnimation, NumberAnimation, Анимация и переходы в Qt Quick и Примеры Qt Quick — Анимация.

Документация по свойствам

duration : int

Это свойство содержит продолжительность анимации в мс, используемой при отслеживании источника.

Установка значения -1 (по умолчанию) отключает значение продолжительности.

Если значения скорости и продолжительности оба включены, анимация будет использовать значение, которое обеспечивает меньшую продолжительность.

maximumEasingTime : int

Это свойство задает максимальное время в мс, которое может занимать любое «сглаживание» при отслеживании. Установка этого свойства приводит к «успокоению» скорости после определенного времени. Установка отрицательного значения возвращает к обычному режиму сглаживания на протяжении всей продолжительности анимации.

Значение по умолчанию равно -1.

reversingMode : перечисление

Устанавливает поведение SmoothedAnimation, если направление анимации меняется на обратное.

Возможные значения:

• SmoothedAnimation.Eased (по умолчанию) — анимация плавно замедлится, а затем изменит направление
• SmoothedAnimation.Immediate — анимация немедленно начнет ускоряться в обратном направлении, начиная со скорости 0
• SmoothedAnimation.Sync — свойство немедленно устанавливается в целевое значение

velocity : real

Это свойство содержит среднюю скорость, разрешенную при отслеживании значения «to».

По умолчанию скорость SmoothedAnimation составляет 200 единиц/секунду.

Установка значения -1 отключает значение скорости.

Если значения скорости и продолжительности оба включены, анимация будет использовать значение, которое обеспечивает меньшую продолжительность.