Область видимости и разрешение имён

Связывания свойств QML, встроенные функции и импортированные JavaScript-файлы выполняются в области видимости JavaScript. Область видимости определяет, к каким переменным может получить доступ выражение, и какую переменную следует использовать в случае конфликта имён.

Поскольку встроенный механизм области видимости JavaScript очень простой, QML расширяет его, чтобы он более естественно соответствовал расширениям языка QML.

Область видимости JavaScript

Расширения области видимости QML не влияют на естественную систему области видимости JavaScript. Программисты на JavaScript могут использовать свои существующие знания при программировании функций, связываний свойств или импортированных JavaScript-файлов в QML.

В следующем примере метод addConstant() будет добавлять 13 к переданному параметру так, как ожидалось от программиста, независимо от значения свойств объекта QML a и b.

QtObject {
    property int a: 3
    property int b: 9

    function addConstant(b) {
        var a = 13;
        return b + a;
    }
}

Факт, что QML соблюдает обычные правила области видимости JavaScript, применим и к связываниям. Это совершенно ужасное связывание присвоит значение 12 свойству объекта QML a.

QtObject {
    property int a

    a: { var a = 12; a; }
}

У каждого JavaScript-выражения, функции или файла в QML есть свой уникальный объект переменных. Локальные переменные, объявленные в одном, никогда не будут конфликтовать с локальными переменными, объявленными в другом.

Имена типов и импортированные JavaScript-файлы

Документы QML включают инструкции import, которые определяют имена типов и JavaScript-файлы, видимые для документа. Помимо использования в самом объявлении QML, имена типов используются кодом JavaScript при доступе к прикреплённым свойствам и значениям перечислений.

Эффект импорта распространяется на каждое связывание свойств и JavaScript-функцию в документе QML, даже на те, что находятся во вложенных встроенных компонентах. Следующий пример демонстрирует простой QML-файл, который обращается к некоторым значениям перечислений и вызывает импортированную JavaScript-функцию.

import QtQuick 2.0
import "code.js" as Code

ListView {
    snapMode: ListView.SnapToItem

    delegate: Component {
        Text {
            elide: Text.ElideMiddle
            text: "A really, really long string that will require eliding."
            color: Code.defaultColor()
        }
    }
}

Объект области видимости связывания

Объект, имеющий связывание свойства, известен как объект области видимости связывания. В следующем примере объект Item является объектом области видимости связывания.

Item {
    anchors.left: parent.left
}

Связывания имеют доступ к свойствам объекта области видимости без квалификации. В предыдущем примере связывание обращается к свойству Item parent напрямую, без необходимости каких-либо префиксов объекта. QML вводит более структурированный, объектно-ориентированный подход к JavaScript и, следовательно, не требует использования JavaScript-свойства this.

При обращении к прикреплённым свойствам из связываний следует проявлять осторожность из-за их взаимодействия с объектом области видимости. Понятие прикреплённых свойств существует для всех объектов, даже если они влияют только на подмножество этих объектов. В результате неквалифицированные чтения прикреплённых свойств всегда будут разрешаться до прикреплённого свойства объекта области видимости, что не всегда соответствует намерениям программиста.

Например, тип PathView прикрепляет свойства интерполированных значений к своим делегатам в зависимости от их положения в пути. Поскольку PathView осмысленно прикрепляет эти свойства только к корневому объекту в делегате, любой дочерний объект, который к ним обращается, должен явно указать корневой объект, как показано ниже.

PathView {
    delegate: Component {
        Rectangle {
            id: root
            Image {
                scale: root.PathView.scale
            }
        }
    }
}

Если объект Image опустил префикс root, он непреднамеренно обратился бы к несброшенному прикреплённому свойству PathView.scale к самому себе.

Область видимости компонента

Каждый QML-компонент в QML-документе определяет логическую область видимости. Каждый документ имеет как минимум один корневой компонент, но также может иметь другие встроенные дочерние компоненты. Область видимости компонента — это объединение идентификаторов объектов внутри компонента и свойств корневого объекта компонента.

Item {
    property string title

    Text {
        id: titletype
        text: "<b>" + title + "</b>"
        font.pixelSize: 22
        anchors.top: parent.top
    }

    Text {
        text: titletype.text
        font.pixelSize: 18
        anchors.bottom: parent.bottom
    }
}

Приведённый выше пример демонстрирует простой QML-компонент, который отображает строку заголовка форматированного текста вверху и меньшую копию того же текста внизу. Первый тип Text напрямую обращается к свойству компонента title при формировании текста для отображения. Возможность прямого доступа к свойствам корневого типа упрощает распределение данных по всему компоненту.

Второй тип Text использует идентификатор для прямого доступа к тексту первого. Идентификаторы явно указываются QML-программистом, поэтому они всегда имеют приоритет над другими именами свойств (за исключением тех, что находятся в области видимости JavaScript). Например, в маловероятном случае, если объект области видимости связывания имел свойство titletype в предыдущем примере, идентификатор titletype по-прежнему имел бы приоритет.

Иерархия экземпляров компонентов

В QML экземпляры компонентов соединяют свои области видимости компонентов, образуя иерархию областей видимости. Экземпляры компонентов могут напрямую получить доступ к областям видимости своих предков.

Самый простой способ продемонстрировать это — с помощью встроенных дочерних компонентов, чьи области видимости компонентов неявно задаются как дочерние по отношению к внешнему компоненту.

Item {
    property color defaultColor: "blue"

    ListView {
        delegate: Component {
            Rectangle {
                color: defaultColor
            }
        }
    }
}

Иерархия экземпляров компонентов позволяет экземплярам компонента делегата получать доступ к свойству defaultColor типа Item. Конечно, если бы компонент делегата имел свойство defaultColor, оно имело бы приоритет.

Иерархия областей видимости экземпляров компонентов распространяется и на вневстроенные компоненты. В следующем примере компонент TitlePage.qml создаёт два экземпляра TitleText. Даже если тип TitleText находится в отдельном файле, он по-прежнему имеет доступ к свойству title при использовании внутри TitlePage. QML — это язык с динамической областью видимости — в зависимости от места использования свойство title может разрешаться по-разному.

// TitlePage.qml
import QtQuick 2.0
Item {
    property string title

    TitleText {
        size: 22
        anchors.top: parent.top
    }

    TitleText {
        size: 18
        anchors.bottom: parent.bottom
    }
}

// TitleText.qml
import QtQuick 2.0
Text {
    property int size
    text: "<b>" + title + "</b>"
    font.pixelSize: size
}

Динамическая область видимости очень мощная, но ею необходимо пользоваться с осторожностью, чтобы предотвратить затруднение предсказуемости поведения QML-кода. В общем случае ею следует пользоваться только в тех случаях, когда два компонента уже тесно связаны каким-либо другим образом. При создании повторно используемых компонентов предпочтительнее использовать интерфейсы свойств, например, так:

// TitlePage.qml
import QtQuick 2.0
Item {
    id: root
    property string title

    TitleText {
        title: root.title
        size: 22
        anchors.top: parent.top
    }

    TitleText {
        title: root.title
        size: 18
        anchors.bottom: parent.bottom
    }
}

// TitleText.qml
import QtQuick 2.0
Text {
    property string title
    property int size

    text: "<b>" + title + "</b>"
    font.pixelSize: size
}

Переопределённые свойства

QML допускает переопределение имён свойств, определённых в объявлении объекта, свойствами, объявленными в другом объявлении объекта, которое расширяет первый. Например:

// Displayable.qml
import QtQuick 2.0
Item {
    property string title
    property string detail

    Text {
        text: "<b>" + title + "</b><br>" + detail
    }

    function getTitle() { return title }
    function setTitle(newTitle) { title = newTitle }
}

// Person.qml
import QtQuick 2.0
Displayable {
    property string title
    property string firstName
    property string lastName

    function fullName()  { return title + " " + firstName + " " + lastName }
}

Здесь имя title присвоено как заголовку вывода текста для Displayable, так и титульному званию объекта Person.

Переопределённое свойство разрешается в соответствии с областью видимости, в которой оно ссылается. Внутри области видимости компонента Person или из внешней области видимости, которая ссылается на экземпляр компонента Person, title разрешается до свойства, объявленного в Person.qml. Функция fullName будет ссылаться на свойство title , объявленное внутри Person.

Однако внутри компонента Displayable title ссылается на свойство, объявленное в Displayable.qml. Функции getTitle() и setTitle(), а также связывание для свойства text объекта Text будут ссылаться на свойство title , объявленное в компоненте Displayable.

Несмотря на одинаковое имя, эти два свойства полностью независимы. Обработчик сигнала onChanged для одного из свойств не будет срабатывать при изменении другого свойства с таким же именем. Псевдоним для любого свойства будет ссылаться на одно или другое, но не на оба.

Объект глобальной области видимости JavaScript

QML запрещает имена типов, идентификаторов и свойств, которые конфликтуют со свойствами глобального объекта, чтобы избежать любых неясностей. Программисты могут быть уверены, что Math.min(10, 9) всегда будет работать как ожидается!

Дополнительную информацию см. в разделе JavaScript Host Environment.