Тип QML Repeater

Создаёт несколько компонентов на основе Item, используя предоставленную модель Подробнее...

• Список всех членов, включая унаследованные

Свойства

• count : int
• delegate : Component
• model : любой

Сигналы

• itemAdded(int index, Item item)
• itemRemoved(int index, Item item)

Методы

• Item itemAt(index)

Подробное описание

Тип Repeater используется для создания большого количества похожих элементов. Как и другие типы представлений, Repeater имеет свойство model и delegate: для каждой записи в модели делегат создаётся в контексте, заполненном данными из модели. Элемент Repeater обычно заключён в тип позиционера, такой как Row или Column, для визуального размещения нескольких элементов делегата, созданных Repeater.

Следующий Repeater создаёт три экземпляра элемента Rectangle внутри Row:

import QtQuick 2.0

Row {
    Repeater {
        model: 3
        Rectangle {
            width: 100; height: 40
            border.width: 1
            color: "yellow"
        }
    }
}

Модель model Repeater может быть любой из поддерживаемых моделей данных. Кроме того, как и делегаты для других представлений, делегат Repeater может получить доступ к своему индексу в пределах повторителя, а также к данным модели, относящимся к делегату. Подробности см. в документации к свойству delegate.

Создаваемые Repeater элементы вставляются в порядке следования в качестве дочерних элементов родителя Repeater. Вставка начинается сразу после позиции повторителя в списке стекирования его родителя. Это позволяет использовать Repeater внутри макета. Например, элементы следующего Repeater размещаются между красным и синим прямоугольником:

Row {
    Rectangle { width: 10; height: 20; color: "red" }
    Repeater {
        model: 10
        Rectangle { width: 20; height: 20; radius: 10; color: "green" }
    }
    Rectangle { width: 10; height: 20; color: "blue" }
}

Примечание: Элемент Repeater владеет всеми созданными им элементами. Удаление или динамическое уничтожение элемента, созданного Repeater, приведёт к непредсказуемому поведению.

Учёт при использовании Repeater

Тип Repeater создаёт все свои элементы делегата при первом создании повторителя. Это может быть неэффективно, если количество элементов делегата велико, и не все элементы необходимо отображать одновременно. В этом случае рассмотрите использование других типов представлений, таких как ListView (который создаёт элементы делегата только при прокрутке в область видимости), или используйте методы Динамическое создание объектов для создания элементов по мере необходимости.

Также обратите внимание, что Repeater основан на Item и может повторять только объекты, производные от Item. Например, его нельзя использовать для повторения QtObjects:

//bad code
Item {
    Can't repeat QtObject as it doesn't derive from Item.
    Repeater {
        model: 10
        QtObject {}
    }
}

Документация по свойствам

count : int

Это свойство содержит количество элементов в повторителе.

[default] delegate : Component

Делегат предоставляет шаблон, определяющий каждый элемент, созданный повторителем.

Делегаты получают доступ к свойству index только для чтения, которое указывает индекс делегата в пределах повторителя. Например, следующий делегат Text отображает индекс каждого повторяющегося элемента:

Column {
    Repeater {
        model: 10
        Text { text: "I'm item " + index }
    }
}

Если модель model является списком строк или списком объектов, делегат также получает доступ к свойству modelData только для чтения, которое содержит строковые или объектные данные. Например:

Column {
    Repeater {
        model: ["apples", "oranges", "pears"]
        Text { text: "Data: " + modelData }
    }
}

Если модель model является объектом модели (например, ListModel), делегат может получить доступ ко всем ролям модели как к именованным свойствам, аналогично тому, как это делают делегаты для типов представлений, таких как ListView.

См. также QML Модели данных.

model : любой

Модель, предоставляющая данные для повторителя.

Это свойство может быть установлено на любую поддерживаемую модель данных:

• Число, указывающее количество делегатов, которые должен создать повторитель
• Модель (например, элемент ListModel или подкласс QAbstractItemModel)
• Список строк
• Список объектов

Тип модели влияет на свойства, доступные для delegate.

См. также Модели данных.

Документация по сигналам

itemAdded(int index, Item item)

Этот сигнал генерируется при добавлении элемента в повторитель. Параметр index содержит индекс, в который был вставлен элемент, а параметр item — добавленный Item.

Соответствующий обработчик — onItemAdded.

itemRemoved(int index, Item item)

Этот сигнал генерируется при удалении элемента из повторителя. Параметр index содержит индекс, из которого был удалён элемент, а параметр item — удалённый Item.

Не сохраняйте ссылку на item, если он был создан этим повторителем, так как в таких случаях он будет удалён вскоре после обработки сигнала.

Соответствующий обработчик — onItemRemoved.

Документация по методам

Item itemAt(index)

Возвращает Item, созданный по заданному index, или null , если элемент по index отсутствует.