Заявления об импорте

Синтаксис оператора импорта

Оператор импорта позволяет клиентам указать движку, какие модули, JavaScript-ресурсы и каталоги компонентов используются в документе QML. Типы, которые могут быть использованы в документе, зависят от импортированных модулей, ресурсов и каталогов.

Типы импорта

Существует три разных типа импорта. Каждый тип импорта имеет немного отличающийся синтаксис и различные семантики применяются к разным типам импорта.

Импорт модулей (пространств имён)

Наиболее распространённый тип импорта — это импорт модуля. Клиенты могут импортировать QML-модули, которые регистрируют типы объектов QML и JavaScript-ресурсы в заданном пространстве имён.

Общий вид импорта модуля:

import <ModuleIdentifier> <Version.Number> [as <Qualifier>]

• <ModuleIdentifier> — это идентификатор, указанный в точечной форме URI, который однозначно идентифицирует пространство имён типов, предоставляемое модулем.
• <Version.Number> — версия в формате MajorVersion.MinorVersion, которая определяет, какие определения различных типов объектов и JavaScript-ресурсов будут доступны благодаря импорту.
• <Qualifier> — необязательный локальный идентификатор пространства имён, в который будут установлены типы объектов и JavaScript-ресурсы, предоставляемые модулем, если он указан. Если он опущен, типы объектов и JavaScript-ресурсы, предоставляемые модулем, будут установлены в глобальное пространство имён.

Пример импорта модуля без квалификатора:

import QtQuick 2.0

Этот импорт позволяет использовать все типы, предоставляемые модулем QtQuick, без необходимости указывать квалификатор. Например, клиентский код для создания прямоугольника выглядит так:

import QtQuick 2.0

Rectangle {
    width: 200
    height: 100
    color: "red"
}

Пример импорта модуля с квалификатором:

import QtQuick 2.0 as Quick

Этот импорт позволяет одновременно импортировать несколько модулей, которые предоставляют конфликтующие имена типов, однако, поскольку каждый вызов типа, предоставляемого модулем, импортированным в квалифицированное пространство имён, должен быть предваряться квалификатором, конфликт однозначно разрешается QML-движком.

Пример клиентского кода, создающего прямоугольник после использования импорта модуля с квалификатором:

import QtQuick 2.0 as Quick

Quick.Rectangle {
    width: 200
    height: 100
    color: "red"
}

Дополнительную информацию об импортах с квалификатором см. в следующем разделе Импорт в квалифицированное локальное пространство имён.

Обратите внимание, что если QML-документ не импортирует модуль, предоставляющий определённый тип объекта QML, но пытается использовать этот тип, произойдёт ошибка. Например, следующий QML-документ не импортирует QtQuick, и поэтому попытка использовать тип Rectangle завершится ошибкой:

Rectangle {
    width: 200
    height: 100
    color: "red"
}

В этом случае движок выведет ошибку и откажется загрузить файл.

Импорт пространств имён, не являющихся модулями

Типы также могут быть зарегистрированы в пространствах имён непосредственно через различные функции регистрации в C++ (например, qmlRegisterType()). Типы, зарегистрированные в пространстве имён таким образом, могут быть импортированы путём импорта пространства имён, как если бы идентификатор пространства имён был идентификатором модуля.

Это наиболее распространено в клиентских приложениях, которые определяют свои собственные типы объектов QML в C++ и регистрируют их в системе типов QML вручную.

Импорт в квалифицированное локальное пространство имён

Оператор import может необязательно использовать ключевое слово as, чтобы указать, что типы должны быть импортированы в определённое локальное пространство имён документа. Если указано пространство имён, то любые ссылки на типы, доступные благодаря импорту, должны предваряться квалификатором локального пространства имён.

Ниже модуль QtQuick импортируется в пространство имён «CoreItems». Теперь любые ссылки на типы из модуля QtQuick должны предваряться именем CoreItems:

import QtQuick 2.0 as CoreItems

CoreItems.Rectangle {
    width: 100; height: 100

    CoreItems.Text { text: "Hello, world!" }

    // WRONG! No namespace prefix - the Text type won't be found
    Text { text: "Hello, world!" }
}

Пространство имён служит идентификатором модуля в рамках файла. Пространство имён не становится атрибутом корневого объекта, на который можно ссылаться извне, как это можно сделать с свойствами, сигналами и методами.

Пространственный импорт полезен, если требуется использовать два QML-типа с одинаковым именем, но расположенных в разных модулях. В этом случае два модуля можно импортировать в разные пространства имён, чтобы гарантировать, что код ссылается на правильный тип:

import QtQuick 2.0 as CoreItems
import "../textwidgets" as MyModule

CoreItems.Rectangle {
    width: 100; height: 100

    MyModule.Text { text: "Hello from my custom text item!" }
    CoreItems.Text { text: "Hello from Qt Quick!" }
}

Обратите внимание, что несколько модулей могут быть импортированы в одно и то же пространство имён, точно так же, как несколько модулей могут быть импортированы в глобальное пространство имён. Например:

import QtQuick 2.0 as Project
import QtMultimedia 5.0 as Project

Project.Rectangle {
    width: 100; height: 50

    Project.Audio {
        source: "music.wav"
        autoPlay: true
    }
}

Импорт каталогов

Каталог, содержащий QML-документы, также может быть импортирован непосредственно в QML-документ. Это обеспечивает простой способ сегментации QML-типов в повторно используемые группы: каталоги на файловой системе.

Общий вид импорта каталога:

import "<DirectoryPath>" [as <Qualifier>]

Примечание: Пути импорта прозрачны по отношению к сети: приложения могут импортировать документы из удалённых путей так же просто, как и из локальных путей. См. общие правила разрешения URL для прозрачности сети в QML-документах. Если каталог удалённый, он должен содержать файл перечисления каталога qmldir, так как QML-движок не может определить содержимое удалённого каталога, если этот qmldir файл не существует.

Аналогичные семантики для <Qualifier> применяются к импортам каталогов, как и к импортам модулей; для получения дополнительной информации см. предыдущий раздел об импорте в квалифицированное локальное пространство имён.

Дополнительную информацию об импорте каталогов см. в подробной документации о импорте каталогов.

Импорт JavaScript-ресурсов

JavaScript-ресурсы могут быть импортированы непосредственно в QML-документ. Каждый JavaScript-ресурс должен иметь идентификатор, по которому к нему обращаются.

Общий вид импорта JavaScript-ресурса:

import "<JavaScriptFile>" as <Identifier>

Обратите внимание, что <Identifier> должен быть уникальным в пределах QML-документа, в отличие от квалификатора локального пространства имён, который может быть применён к импортам модулей.

JavaScript-ресурсы из модулей

JavaScript-файлы могут предоставляться модулями, добавляя определения идентификаторов в файл qmldir, который определяет модуль.

Например, если модуль projects.MyQMLProject.MyFunctions указан с помощью файла qmldir и установлен в путь QML-импорта:

module projects.MyQMLProject.MyFunctions
SystemFunctions 1.0 SystemFunctions.js
UserFunctions 1.0 UserFunctions.js

клиентское приложение может импортировать JavaScript-ресурсы, объявленные в модуле, импортировав модуль и использовав связанный с объявленным ресурсом идентификатор:

import QtQuick 2.0
import projects.MyQMLProject.MyFunctions 1.0

Item {
    Component.onCompleted: { SystemFunctions.cleanUp(); }
}

Если модуль был импортирован в локальное пространство имён документа, идентификаторы JavaScript-ресурсов должны предваряться квалификатором пространства имён, чтобы их можно было использовать:

import QtQuick 2.0
import projects.MyQMLProject.MyFunctions 1.0 as MyFuncs
import org.example.Functions 1.0 as TheirFuncs

Item {
    Component.onCompleted: {
        MyFuncs.SystemFunctions.cleanUp();
        TheirFuncs.SystemFunctions.shutdown();
    }
}

Дополнительная информация

Дополнительную информацию о JavaScript-ресурсах см. в документации о определении JavaScript-ресурсов в QML, а дополнительную информацию о том, как импортировать JavaScript-ресурсы и как импорты могут использоваться внутри JavaScript-ресурсов, см. в подробной документации о импорте JavaScript-ресурсов в QML.

Путь импорта QML

При импорте идентифицированного модуля QML-движок ищет соответствующий модуль в пути импорта.

Этот путь импорта, возвращаемый QQmlEngine::importPathList(), определяет стандартные места, которые движок будет искать. По умолчанию этот список содержит:

• Каталог текущего файла
• Расположение, указанное в QLibraryInfo::Qml2ImportsPath
• Пути, указанные в переменной среды QML2_IMPORT_PATH
• Путь qrc:/qt-project.org/imports внутри ресурсов.

Дополнительные пути импорта могут быть добавлены с помощью QQmlEngine::addImportPath() или переменной среды QML2_IMPORT_PATH. При запуске инструмента qmlscene вы также можете использовать опцию -I для добавления пути импорта.

Отладка

Переменная среды QML_IMPORT_TRACE может быть полезной для отладки при возникновении проблем с поиском и загрузкой модулей. Подробнее см. Отладка импорта модулей.