Тип QML Flipable

Обеспечивает поверхность, которая может быть перевернута. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• back : Элемент
• front : Элемент
• side : перечисление

Подробное описание

Flipable — это элемент, который может быть визуально «перевернут» между передней и задней сторонами, как карточка. Его можно использовать вместе с Rotation, State и Transition, чтобы создать эффект переворачивания.

Свойства front и back используются для размещения элементов, которые отображаются соответственно на передней и задней сторонах элемента flipable.

Пример использования

Следующий пример демонстрирует элемент Flipable, который переворачивается при нажатии, вращаясь вокруг оси y.

У этого элемента flipable есть flipped булево свойство, которое переключается всякий раз, когда нажимают на MouseArea внутри flipable. Когда flipped равно true, элемент переходит в состояние «back»; в этом состоянии, angle элемента Rotation изменяется на 180 градусов, чтобы создать эффект переворачивания. Когда flipped равно false, элемент возвращается в исходное состояние, в котором значение angle равно 0.

import QtQuick 2.0

Flipable {
    id: flipable
    width: 240
    height: 240

    property bool flipped: false

    front: Image { source: "front.png"; anchors.centerIn: parent }
    back: Image { source: "back.png"; anchors.centerIn: parent }

    transform: Rotation {
        id: rotation
        origin.x: flipable.width/2
        origin.y: flipable.height/2
        axis.x: 0; axis.y: 1; axis.z: 0     // set axis.y to 1 to rotate around y-axis
        angle: 0    // the default angle
    }

    states: State {
        name: "back"
        PropertyChanges { target: rotation; angle: 180 }
        when: flipable.flipped
    }

    transitions: Transition {
        NumberAnimation { target: rotation; property: "angle"; duration: 4000 }
    }

    MouseArea {
        anchors.fill: parent
        onClicked: flipable.flipped = !flipable.flipped
    }
}

Тип Transition создает анимацию, которая изменяет угол за четыре секунды. Когда элемент переключается между состояниями «back» и стандартным, NumberAnimation анимирует угол между его старым и новым значениями.

Подробную информацию о изменениях состояния и стандартном состоянии см. в разделе Qt Quick States, а более подробную информацию об анимациях в пределах переходов см. в разделе Анимация и переходы в Qt Quick.

См. также UI-компоненты: Пример Flipable.

Документация по свойствам

Передняя и задняя стороны flipable.

side : перечисление

Сторона Flipable, которая в данный момент отображается. Возможные значения: Flipable.Front и Flipable.Back.