Тип QML AnchorChanges

Указывает, как изменить привязки элемента в состоянии. Подробнее...

• Список всех членов, включая унаследованные члены

Свойства

• anchors
  • anchors.baseline : AnchorLine
  • anchors.bottom : AnchorLine
  • anchors.horizontalCenter : AnchorLine
  • anchors.left : AnchorLine
  • anchors.right : AnchorLine
  • anchors.top : AnchorLine
  • anchors.verticalCenter : AnchorLine
• target : Item

Подробное описание

Тип AnchorChanges используется для изменения привязок элемента в состоянии.

AnchorChanges нельзя использовать для изменения отступов элемента. Для этого используйте PropertyChanges вместо этого.

В следующем примере мы меняем верхнюю и нижнюю привязки элемента с помощью AnchorChanges, а верхние и нижние отступы привязок с помощью PropertyChanges:

import QtQuick 2.0

Rectangle {
    id: window
    width: 120; height: 120
    color: "black"

    Rectangle { id: myRect; width: 50; height: 50; color: "red" }

    states: State {
        name: "reanchored"

        AnchorChanges {
            target: myRect
            anchors.top: window.top
            anchors.bottom: window.bottom
        }
        PropertyChanges {
            target: myRect
            anchors.topMargin: 10
            anchors.bottomMargin: 10
        }
    }

    MouseArea { anchors.fill: parent; onClicked: window.state = "reanchored" }
}

AnchorChanges можно анимировать с помощью AnchorAnimation.

//animate our anchor changes
Transition {
    AnchorAnimation {}
}

Изменения отступов привязок можно анимировать с помощью NumberAnimation.

Дополнительную информацию о привязках см. в разделе Макеты с привязками.

Документация по свойствам

anchors.baseline : AnchorLine

Эти свойства изменяют соответствующие привязки элемента.

Чтобы сбросить привязку, можно назначить undefined:

AnchorChanges {
    target: myItem
    anchors.left: undefined          //remove myItem's left anchor
    anchors.right: otherItem.right
}

target : Item

Это свойство содержит элемент, к которому будут применены изменения привязок.