Тип QML Tumbler

Поворотное колесо элементов, которые можно выбрать. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• count : int
• currentIndex : int
• currentItem : Item
• delegate : Component
• model : variant
• moving : bool
• visibleItemCount : int
• wrap : bool

Присоединенные свойства

• displacement : real
• tumbler : Tumbler

Методы

• void positionViewAtIndex(int index, PositionMode mode)

Подробное описание

Tumbler {
    model: 5
    // ...
}

Tumbler позволяет пользователю выбрать вариант из вращающегося "колеса" элементов. Это полезно, когда вариантов слишком много, чтобы использовать, например, RadioButton, и слишком мало вариантов, чтобы потребовалось использовать редактируемый SpinBox. Удобно тем, что не требует использования клавиатуры и перематывается к каждому концу, когда элементов много.

API похож на API представлений, таких как ListView и PathView; можно задать модель и представление, а свойства count и currentItem обеспечивают чтение информации о представлении. Для размещения представления в определенном индексе используйте positionViewAtIndex().

Однако, в отличие от представлений, таких как PathView и ListView, всегда есть текущий элемент (если модель не пуста). Это означает, что когда count равен 0, currentIndex будет -1. Во всех остальных случаях он будет больше или равен 0.

По умолчанию, Tumbler перематывается при достижении верхней и нижней границы, если в модели больше элементов, чем видимых; то есть, когда count больше, чем visibleItemCount:

import QtQuick
import QtQuick.Window
import QtQuick.Controls

Rectangle {
    width: frame.implicitWidth + 10
    height: frame.implicitHeight + 10

    function formatText(count, modelData) {
        var data = count === 12 ? modelData + 1 : modelData;
        return data.toString().length < 2 ? "0" + data : data;
    }

    FontMetrics {
        id: fontMetrics
    }

    Component {
        id: delegateComponent

        Label {
            text: formatText(Tumbler.tumbler.count, modelData)
            opacity: 1.0 - Math.abs(Tumbler.displacement) / (Tumbler.tumbler.visibleItemCount / 2)
            horizontalAlignment: Text.AlignHCenter
            verticalAlignment: Text.AlignVCenter
            font.pixelSize: fontMetrics.font.pixelSize * 1.25
        }
    }

    Frame {
        id: frame
        padding: 0
        anchors.centerIn: parent

        Row {
            id: row

            Tumbler {
                id: hoursTumbler
                model: 12
                delegate: delegateComponent
            }

            Tumbler {
                id: minutesTumbler
                model: 60
                delegate: delegateComponent
            }

            Tumbler {
                id: amPmTumbler
                model: ["AM", "PM"]
                delegate: delegateComponent
            }
        }
    }
}

См. также Настройка Tumbler и Элементы управления вводом.

Документация по свойствам

[только для чтения] count : int

Это свойство содержит количество элементов в модели.

currentIndex : int

Это свойство содержит индекс текущего элемента.

Значение этого свойства равно -1 когда count равен 0. Во всех остальных случаях он будет больше или равен 0.

См. также currentItem и positionViewAtIndex().

[только для чтения] currentItem : Item

Это свойство содержит элемент в текущем индексе.

См. также currentIndex и positionViewAtIndex().

delegate : Component

Это свойство содержит делегат, используемый для отображения каждого элемента.

model : variant

Это свойство содержит модель, которая предоставляет данные для этого Tumbler.

[с QtQuick.Controls 2.2 (Qt 5.9)] moving : bool

Это свойство описывает, движется ли Tumbler в данный момент, из-за того, что пользователь его перетаскивает или отпускает.

Это свойство было добавлено в QtQuick.Controls 2.2 (Qt 5.9).

visibleItemCount : int

Это свойство содержит количество элементов, видимых в Tumbler. Оно должно быть нечетным числом, так как текущий элемент всегда центрирован вертикально.

[с QtQuick.Controls 2.1 (Qt 5.8)] wrap : bool

Это свойство определяет, будет ли Tumbler перематываться при достижении верхней или нижней границы.

Значение по умолчанию — false, когда count меньше visibleItemCount, так как взаимодействие с неперематываемым Tumbler проще при небольшом количестве элементов. Для переопределения этого поведения явно задайте значение этого свойства. Чтобы вернуться к поведению по умолчанию, установите это свойство в undefined.

Это свойство было добавлено в QtQuick.Controls 2.1 (Qt 5.8).

Документация по присоединенным свойствам

[только для чтения] Tumbler.displacement : real

Это присоединенное свойство содержит значение от -visibleItemCount / 2 до visibleItemCount / 2, которое представляет, насколько далеко этот элемент находится от текущего элемента, где 0 означает полную текучесть.

Например, элемент будет иметь непрозрачность 40%, когда он не является текущим, и перейдет к 100% непрозрачности, когда станет текущим:

delegate: Text {
    text: modelData
    opacity: 0.4 + Math.max(0, 1 - Math.abs(Tumbler.displacement)) * 0.6
}

[только для чтения] Tumbler.tumbler : Tumbler

Это присоединенное свойство содержит Tumbler. Свойство может быть присоединено к делегату Tumbler. Значение — null, если элемент не является делегатом Tumbler.

Документация по методам

[since QtQuick.Controls 2.5 (Qt 5.12)] void positionViewAtIndex(int index, PositionMode mode)

Размещает представление таким образом, чтобы index находился в позиции, заданной mode.

Например:

positionViewAtIndex(10, Tumbler.Center)

Если wrap равно true (по умолчанию), доступны режимы PathView's positionViewAtIndex(), иначе — режимы ListView's positionViewAtIndex().

Примечание: Известно, что использование Tumbler.Beginning при wrap true приведет к размещению неправильного элемента вверху представления. В качестве обходного пути передайте index - 1.

Этот метод был добавлен в QtQuick.Controls 2.5 (Qt 5.12).

См. также currentIndex.