Тип QML Flipable

Обеспечивает поверхность, которую можно перевернуть. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• back : Item
• front : Item
• side : перечисление

Подробное описание

Flipable — это элемент, который можно визуально «переворачивать» между передней и задней сторонами, как карточку. Его можно использовать вместе с Rotation, State и Transition, чтобы создать эффект переворачивания.

Свойства front и back используются для хранения элементов, отображаемых соответственно на передней и задней сторонах элемента flipable.

Пример использования

В следующем примере показан элемент Flipable, который переворачивается при нажатии, вращаясь вокруг оси y.

У этого элемента flipable есть свойство flipped типа boolean, которое переключается при нажатии на MouseArea внутри flipable. Когда flipped истинно, элемент переходит в состояние «обратная сторона»; в этом состоянии angle элемента Rotation изменяется на 180 градусов для создания эффекта переворачивания. Когда flipped ложно, элемент возвращается в исходное состояние, в котором значение angle равно 0.

import QtQuick 2.0

Flipable {
    id: flipable
    width: 240
    height: 240

    property bool flipped: false

    front: Image { source: "front.png"; anchors.centerIn: parent }
    back: Image { source: "back.png"; anchors.centerIn: parent }

    transform: Rotation {
        id: rotation
        origin.x: flipable.width/2
        origin.y: flipable.height/2
        axis.x: 0; axis.y: 1; axis.z: 0     // set axis.y to 1 to rotate around y-axis
        angle: 0    // the default angle
    }

    states: State {
        name: "back"
        PropertyChanges { target: rotation; angle: 180 }
        when: flipable.flipped
    }

    transitions: Transition {
        NumberAnimation { target: rotation; property: "angle"; duration: 4000 }
    }

    MouseArea {
        anchors.fill: parent
        onClicked: flipable.flipped = !flipable.flipped
    }
}

Тип Transition создает анимацию, меняющую угол за четыре секунды. Когда элемент переключается между состояниями «обратная сторона» и исходным, NumberAnimation анимирует угол между его старым и новым значениями.

Подробную информацию о сменах состояний и исходном состоянии см. в разделе Qt Quick States, а дополнительную информацию об анимациях в рамках переходов см. в разделе Анимация и переходы в Qt Quick.

См. также UI-компоненты: пример Flipable.

Документация свойств

Передняя и задняя стороны flipable.

side : перечисление

Сторона Flipable, которая в данный момент видна. Возможные значения — Flipable.Front и Flipable.Back.