Анимация и переходы в Qt Quick

Типы анимации и переходов

• Transition — Анимирует переходы во время смены состояний
• SequentialAnimation — Выполняет анимации последовательно
• ParallelAnimation — Выполняет анимации параллельно
• Behavior — Указывает стандартную анимацию для изменений свойств
• PropertyAction — Устанавливает мгновенные изменения свойств во время анимации
• PauseAnimation — Вводит паузу в анимации
• SmoothedAnimation — Позволяет свойству плавно следовать за значением
• SpringAnimation — Позволяет свойству следовать за значением с пружинным движением
• ScriptAction — Выполняет скрипты во время анимации

Типы, которые анимируют свойства на основе типов данных

Анимации создаются путем применения типов анимации к значениям свойств. Типы анимации будут интерполировать значения свойств, чтобы создать плавные переходы. Также переходы состояний могут назначать анимации для изменений состояний.

Для создания анимации используйте соответствующий тип анимации для типа свойства, которое требуется анимировать, и примените анимацию в зависимости от необходимого типа поведения.

Запуск анимаций

Существует несколько способов назначения анимации объекту.

Прямая анимация свойств

Анимации создаются путем применения анимационных объектов к значениям свойств, чтобы постепенно изменять свойства со временем. Эти анимации свойств применяют плавные движения, интерполируя значения между изменениями значений свойств. Анимации свойств обеспечивают управление временем и позволяют использовать различные интерполяции с помощью кривых сглаживания.

Rectangle {
    id: flashingblob
    width: 75; height: 75
    color: "blue"
    opacity: 1.0

    MouseArea {
        anchors.fill: parent
        onClicked: {
            animateColor.start()
            animateOpacity.start()
        }
    }

    PropertyAnimation {id: animateColor; target: flashingblob; properties: "color"; to: "green"; duration: 100}

    NumberAnimation {
        id: animateOpacity
        target: flashingblob
        properties: "opacity"
        from: 0.99
        to: 1.0
        loops: Animation.Infinite
        easing {type: Easing.OutBack; overshoot: 500}
   }
}

Специализированные типы анимации свойств имеют более эффективные реализации, чем тип PropertyAnimation. Они предназначены для назначения анимаций к различным типам QML, таким как int, color, и повороты. Аналогично, ParentAnimation может анимировать изменения родителя.

Дополнительную информацию о различных свойствах анимации см. в разделе Управление анимациями.

Использование предопределенных целей и свойств

В предыдущем примере объектам PropertyAnimation и NumberAnimation необходимо было указать конкретные значения цели и свойств для указания объектов и свойств, которые должны быть анимированы. Этого можно избежать, используя синтаксис <Animation> на <Свойство>, который указывает, что анимация должна применяться в качестве источника значения свойства.

Ниже приведены два объекта PropertyAnimation, которые указаны с использованием этого синтаксиса:

import QtQuick 2.0

Rectangle {
    id: rect
    width: 100; height: 100
    color: "red"

    PropertyAnimation on x { to: 100 }
    PropertyAnimation on y { to: 100 }
}

Анимация запускается сразу после загрузки прямоугольника и будет автоматически применена к его x и y значениям. Поскольку был использован синтаксис <Animation> на <Свойство>, не нужно устанавливать значение цели объектов PropertyAnimation на rect, а также не нужно устанавливать значения свойств свойства на x и y.

Это также может быть использовано для группированных анимаций, чтобы убедиться, что все анимации в группе применяются к одному свойству. Например, предыдущий пример можно вместо этого использовать SequentialAnimation для анимации цвета прямоугольника сначала в желтый, затем в синий:

import QtQuick 2.0

Rectangle {
    width: 100; height: 100
    color: "red"

    SequentialAnimation on color {
        ColorAnimation { to: "yellow"; duration: 1000 }
        ColorAnimation { to: "blue"; duration: 1000 }
    }
}

Поскольку объект SequentialAnimation указан на свойстве color с использованием синтаксиса <Animation> на <Свойство>, его дочерние объекты ColorAnimation также автоматически применяются к этому свойству и не нуждаются в указании значений анимации цели или свойства.

Переходы при изменении состояний

Состояния Qt Quick — это конфигурации свойств, в которых свойство может иметь разные значения, отражающие разные состояния. Изменения состояний вызывают внезапные изменения свойств; анимации сглаживают переходы, чтобы изменения состояний были визуально привлекательными.

Тип Transition может содержать типы анимаций для интерполяции изменений свойств, вызванных изменениями состояния. Чтобы назначить переход объекту, свяжите его со свойством transitions.

Кнопка может иметь два состояния, состояние pressed при нажатии пользователем на кнопку и состояние released при отпускании пользователем кнопки. Мы можем назначить различные конфигурации свойств для каждого состояния. Переход будет анимировать изменение от состояния pressed до состояния released. Аналогичным образом, при переходе от состояния released к состоянию pressed будет происходить анимация.

Rectangle {
    width: 75; height: 75
    id: button
    state: "RELEASED"

    MouseArea {
        anchors.fill: parent
        onPressed: button.state = "PRESSED"
        onReleased: button.state = "RELEASED"
    }

    states: [
        State {
            name: "PRESSED"
            PropertyChanges { target: button; color: "lightblue"}
        },
        State {
            name: "RELEASED"
            PropertyChanges { target: button; color: "lightsteelblue"}
        }
    ]

    transitions: [
        Transition {
            from: "PRESSED"
            to: "RELEASED"
            ColorAnimation { target: button; duration: 100}
        },
        Transition {
            from: "RELEASED"
            to: "PRESSED"
            ColorAnimation { target: button; duration: 100}
        }
    ]
}

Связывание свойств to и from с именем состояния назначит этот конкретный переход изменению состояния. Для простых или симметричных переходов установка свойства to на символ подстановки «*» означает, что переход применим к любому изменению состояния.

    transitions:
        Transition {
            to: "*"
            ColorAnimation { target: button; duration: 100}
        }

Стандартная анимация как поведение

Стандартные анимации свойств устанавливаются с помощью анимаций поведения. Анимации, объявленные в типах Behavior, применяются к свойству и анимируют любые изменения значения свойства. Однако типы Behavior имеют свойство enabled для преднамеренного включения или отключения анимаций поведения.

Компонент шара может иметь анимацию поведения, назначенную его x, y, и color свойствам. Анимация поведения может быть настроена для имитации эффекта упругости. По сути, эта анимация поведения будет применять эффект упругости к свойствам всякий раз, когда шар перемещается.

Rectangle {
    width: 75; height: 75; radius: width
    id: ball
    color: "salmon"

    Behavior on x {
        NumberAnimation {
            id: bouncebehavior
            easing {
                type: Easing.OutElastic
                amplitude: 1.0
                period: 0.5
            }
        }
    }
    Behavior on y {
        animation: bouncebehavior
    }
    Behavior {
        ColorAnimation { target: ball; duration: 100 }
    }
}

Существует несколько способов назначения анимаций поведения свойствам. Объявление Behavior on <property> является удобным способом назначения анимации поведения на свойство.

См. примеры Qt Quick - Анимация Qt Quick Examples - Animation для демонстрации анимаций поведения.

Выполнение анимаций параллельно или последовательно

Анимации могут выполняться параллельно или последовательно. Параллельные анимации будут воспроизводить группу анимаций одновременно, а последовательные анимации будут воспроизводить группу анимаций в порядке: одна за другой. Группирование анимаций в SequentialAnimation и ParallelAnimation будет воспроизводить анимации последовательно или параллельно.

Компонент баннера может иметь несколько значков или слоганов для отображения один за другим. Свойство opacity может преобразовываться в 1.0, обозначающее непрозрачный объект. Используя тип SequentialAnimation, анимации непрозрачности будут воспроизводиться после завершения предыдущей анимации. Тип ParallelAnimation будет воспроизводить анимации одновременно.

Rectangle {
    id: banner
    width: 150; height: 100; border.color: "black"

    Column {
        anchors.centerIn: parent
        Text {
            id: code
            text: "Code less."
            opacity: 0.01
        }
        Text {
            id: create
            text: "Create more."
            opacity: 0.01
        }
        Text {
            id: deploy
            text: "Deploy everywhere."
            opacity: 0.01
        }
    }

    MouseArea {
        anchors.fill: parent
        onPressed: playbanner.start()
    }

    SequentialAnimation {
        id: playbanner
        running: false
        NumberAnimation { target: code; property: "opacity"; to: 1.0; duration: 200}
        NumberAnimation { target: create; property: "opacity"; to: 1.0; duration: 200}
        NumberAnimation { target: deploy; property: "opacity"; to: 1.0; duration: 200}
    }
}

После размещения отдельных анимаций в SequentialAnimation или ParallelAnimation, их больше нельзя запускать и останавливать независимо. Последовательная или параллельная анимация должна запускаться и останавливаться как группа.

Тип SequentialAnimation также полезен для воспроизведения анимаций переходов, потому что анимации воспроизводятся параллельно внутри переходов.

Управление анимациями

Существуют различные методы управления анимациями.

Воспроизведение анимации

Все типы анимаций наследуют от типа Animation. Невозможно создать объекты Animation; вместо этого этот тип предоставляет основные свойства и методы для типов анимации. Типы анимаций имеют start(), stop(), resume(), pause(), restart(), и complete() — все эти методы управляют выполнением анимаций.

Сглаживание

Кривые сглаживания определяют, как анимация будет интерполироваться между начальным и конечным значениями. Разные кривые сглаживания могут выходить за пределы определенного диапазона интерполяции. Кривые сглаживания упрощают создание эффектов анимации, таких как эффекты отскока, ускорения, замедления и циклические анимации.

Объект QML может иметь различные кривые сглаживания для каждой анимации свойств. Также существуют различные параметры для управления кривой, некоторые из которых являются уникальными для определенной кривой. Для получения дополнительной информации о кривых сглаживания посетите документацию сглаживания.

Пример сглаживания наглядно демонстрирует каждый тип сглаживания.

Другие типы анимации

Кроме того, QML предоставляет несколько других типов, полезных для анимации:

• PauseAnimation: позволяет вставлять паузы во время анимации
• ScriptAction: позволяет выполнять JavaScript во время анимации и может использоваться совместно с StateChangeScript для повторного использования существующих скриптов
• PropertyAction: изменяет свойство немедленно во время анимации, без анимации изменения свойства

Это специализированные типы анимации, которые анимируют различные типы свойств

• SmoothedAnimation: специализированная NumberAnimation, которая обеспечивает плавные изменения в анимации при изменении целевого значения
• SpringAnimation: обеспечивает анимацию пружины со специализированными атрибутами, такими как масса, затухание и эпсилон
• ParentAnimation: используется для анимации изменения родителя (см. ParentChange)
• AnchorAnimation: используется для анимации изменения якоря (см. AnchorChanges)

Использование экземпляров анимации

Использование экземпляров анимации между переходами или поведением не поддерживается и может привести к неопределенному поведению. В следующем примере изменения положения Rectangle, скорее всего, не будут правильно анимированы.

Rectangle {
    // NOT SUPPORTED: this will not work correctly as both Behaviors
    // try to control a single animation instance
    NumberAnimation { id: anim; duration: 300; easing.type: Easing.InBack }
    Behavior on x { animation: anim }
    Behavior on y { animation: anim }
}

Самый простой способ исправить это — повторить NumberAnimation для обоих поведений. Если повторная анимация достаточно сложна, вы также можете создать пользовательский компонент анимации и назначить экземпляр каждому поведению, например:

// MyNumberAnimation.qml
NumberAnimation { id: anim; duration: 300; easing.type: Easing.InBack }

// main.qml
Rectangle {
    Behavior on x { MyNumberAnimation {} }
    Behavior on y { MyNumberAnimation {} }
}

См. также Примеры Qt Quick — Анимация.